fix(test-published-dependencies): declare JUnit launcher

Update the published dependency test builds to use Kotlin DSL task accessors and provider-backed configuration resolution.

Add junit-platform-launcher alongside the JUnit BOM update because the missing launcher caused test execution problems at least on Gradle 9.5.

Author: bric3

test-published-dependencies/agent-logs-on-java-7/build.gradle.kts

@@ -1,3 +1,14 @@
+import org.gradle.api.file.ConfigurableFileCollection
+import org.gradle.api.file.RegularFileProperty
+import org.gradle.api.tasks.Classpath
+import org.gradle.api.tasks.InputFile
+import org.gradle.api.tasks.PathSensitive
+import org.gradle.api.tasks.PathSensitivity
+import org.gradle.kotlin.dsl.application
+import org.gradle.kotlin.dsl.invoke
+import org.gradle.kotlin.dsl.java
+import org.gradle.process.CommandLineArgumentProvider
+
 plugins {
   java
   application
@@ -14,25 +25,46 @@ java {
   targetCompatibility = JavaVersion.VERSION_1_7
 }
 
-val agent: Configuration by configurations.creating
+val agent = configurations.register("agent")
 
 dependencies {
   agent("com.datadoghq:dd-java-agent:$version")
-  testImplementation(platform("org.junit:junit-bom:5.9.2"))
+  testImplementation(platform("org.junit:junit-bom:5.14.1"))
   testImplementation("org.junit.jupiter:junit-jupiter")
+  testRuntimeOnly("org.junit.platform:junit-platform-launcher")
+}
+
+abstract class AgentLogsOnJava7JvmArguments : CommandLineArgumentProvider {
+  @get:Classpath
+  abstract val agentClasspath: ConfigurableFileCollection
+
+  @get:InputFile
+  @get:PathSensitive(PathSensitivity.RELATIVE)
+  abstract val appJar: RegularFileProperty
+
+  override fun asArguments(): Iterable<String> = listOf(
+    "-Dtest.published.dependencies.agent=${agentClasspath.singleFile}",
+    "-Dtest.published.dependencies.jar=${appJar.get().asFile}",
+  )
 }
 
-tasks.named<Test>("test") {
-  dependsOn("jar")
+val jarTask = tasks.jar
+
+tasks.test {
+  dependsOn(jarTask)
   useJUnitPlatform()
   testLogging {
     events("passed", "skipped", "failed")
   }
-  jvmArgs("-Dtest.published.dependencies.agent=${agent.singleFile}")
-  jvmArgs("-Dtest.published.dependencies.jar=${tasks.jar.get().archiveFile.get()}")
+  jvmArgumentProviders.add(
+    objects.newInstance(AgentLogsOnJava7JvmArguments::class.java).apply {
+      agentClasspath.from(agent)
+      appJar.set(jarTask.flatMap { it.archiveFile })
+    }
+  )
 }
 
-tasks.named<Jar>("jar") {
+tasks.jar {
   manifest {
     attributes("Main-Class" to "test.published.dependencies.App")
   }
@@ -42,7 +74,7 @@ application {
   mainClass = "test.published.dependencies.App"
 }
 
-tasks.named<JavaCompile>("compileTestJava") {
+tasks.compileTestJava {
   sourceCompatibility = JavaVersion.VERSION_1_8.toString()
   targetCompatibility = JavaVersion.VERSION_1_8.toString()
 }

test-published-dependencies/ot-is-shaded/build.gradle.kts

@@ -5,7 +5,7 @@ plugins {
   java
 }
 
-val jarfile: Configuration by configurations.creating
+val jarfile = configurations.register("jarfile")
 
 dependencies {
   jarfile("com.datadoghq:dd-trace-ot:$version")
@@ -66,9 +66,9 @@ abstract class CheckJarContentsTask : DefaultTask() {
   }
 }
 
-val jarFile = jarfile.filter { it.name.startsWith("dd-trace-ot") }.singleFile
+val jarFile = layout.file(jarfile.map { it.filter { file -> file.name.startsWith("dd-trace-ot") }.singleFile })
 
-tasks.register<CheckJarContentsTask>("checkJarContents") {
+val checkJarContents = tasks.register<CheckJarContentsTask>("checkJarContents") {
   file.set(jarFile)
   expectedPatterns.set(
     listOf(
@@ -93,16 +93,18 @@ tasks.register<CheckJarContentsTask>("checkJarContents") {
   )
 }
 
-tasks.register("checkJarSize") {
+val checkJarSize = tasks.register("checkJarSize") {
   inputs.file(jarFile)
   doLast {
+    val jar = jarFile.get().asFile
     // Arbitrary limit to prevent unintentional increases to the dd-trace-ot jar size
     // Raise or lower as required
-    assert(jarFile.length() <= 8 * 1024 * 1024)
+    if (jar.length() > 8 * 1024 * 1024) {
+      throw GradleException("jar size is too big: ${jar.length()} bytes")
+    }
   }
 }
 
-tasks.named("check") {
-  dependsOn("checkJarContents")
-  dependsOn("checkJarSize")
+tasks.check {
+  dependsOn(checkJarContents, checkJarSize)
 }

test-published-dependencies/ot-pulls-in-api/build.gradle.kts

@@ -9,11 +9,12 @@ java {
 
 dependencies {
   implementation("com.datadoghq:dd-trace-ot:$version")
-  testImplementation(platform("org.junit:junit-bom:5.9.2"))
+  testImplementation(platform("org.junit:junit-bom:5.14.1"))
   testImplementation("org.junit.jupiter:junit-jupiter")
+  testRuntimeOnly("org.junit.platform:junit-platform-launcher")
 }
 
-tasks.named<Test>("test") {
+tasks.test {
   useJUnitPlatform()
   testLogging {
     events("passed", "skipped", "failed")