GdxVideoDesktopAndroidNative/CMakeLists.txt at master · ModinMobileSTS/GdxVideoDesktopAndroidNative · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
cmake_minimum_required(VERSION 3.22)

project(gdx_video_desktop_android C CXX)

set(CMAKE_C_STANDARD 11)
set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

if (NOT ANDROID)
    message(FATAL_ERROR "This project is intended to be built with Android NDK toolchain.")
endif()

set(FFMPEG_ROOT "${CMAKE_CURRENT_SOURCE_DIR}/third_party/ffmpeg/build/${ANDROID_ABI}")
set(FFMPEG_INCLUDE_DIR "${FFMPEG_ROOT}/include")
set(FFMPEG_LIB_DIR "${FFMPEG_ROOT}/lib")
set(FFMPEG_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/third_party/ffmpeg/source")
set(FFMPEG_WORK_DIR "${CMAKE_CURRENT_SOURCE_DIR}/third_party/ffmpeg/work/${ANDROID_ABI}")

foreach(libname avformat avcodec avutil swscale swresample)
    if (NOT EXISTS "${FFMPEG_LIB_DIR}/lib${libname}.a")
        message(FATAL_ERROR
            "Missing FFmpeg static library: ${FFMPEG_LIB_DIR}/lib${libname}.a\n"
            "Run scripts/build_ffmpeg_android.ps1 first.")
    endif()
endforeach()

add_library(avformat STATIC IMPORTED)
set_target_properties(avformat PROPERTIES IMPORTED_LOCATION "${FFMPEG_LIB_DIR}/libavformat.a")

add_library(avcodec STATIC IMPORTED)
set_target_properties(avcodec PROPERTIES IMPORTED_LOCATION "${FFMPEG_LIB_DIR}/libavcodec.a")

add_library(avutil STATIC IMPORTED)
set_target_properties(avutil PROPERTIES IMPORTED_LOCATION "${FFMPEG_LIB_DIR}/libavutil.a")

add_library(swscale STATIC IMPORTED)
set_target_properties(swscale PROPERTIES IMPORTED_LOCATION "${FFMPEG_LIB_DIR}/libswscale.a")

add_library(swresample STATIC IMPORTED)
set_target_properties(swresample PROPERTIES IMPORTED_LOCATION "${FFMPEG_LIB_DIR}/libswresample.a")

add_library(gdx-video-desktop SHARED
    src/main/cpp/jni_bridge.cpp
    src/main/cpp/VideoDecoder.cpp
    src/main/cpp/Utilities.cpp
    src/main/cpp/Thread.cpp
    src/main/cpp/memcpy_wrap.c
)

target_include_directories(gdx-video-desktop PRIVATE
    "${CMAKE_CURRENT_SOURCE_DIR}/src/main/cpp"
    "${FFMPEG_INCLUDE_DIR}"
    "${FFMPEG_SOURCE_DIR}"
    "${FFMPEG_WORK_DIR}"
)

if (ANDROID_ABI STREQUAL "arm64-v8a")
    set_target_properties(gdx-video-desktop PROPERTIES OUTPUT_NAME "gdx-video-desktoparm64")
elseif (ANDROID_ABI STREQUAL "armeabi-v7a")
    set_target_properties(gdx-video-desktop PROPERTIES OUTPUT_NAME "gdx-video-desktoparm")
endif()

target_link_libraries(gdx-video-desktop
    avformat
    avcodec
    swresample
    swscale
    avutil
    android
    log
    m
    z
    atomic
)