BendableCuboids/build.gradle at main · PlayerAnimationLibrary/BendableCuboids · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
import org.redlance.dima_dencep.gradle.publish2discord.tasks.PublishDiscordTask
import org.apache.commons.lang3.StringUtils

plugins {
    id "org.redlance.dima_dencep.gradle.PublishToDiscord" version "1.0.6"
    id "com.gradleup.shadow" version "9.2.2" apply false
    id "architectury-plugin" version "3.4-SNAPSHOT"
    id "dev.architectury.loom" version "1.13-SNAPSHOT" apply false
}

architectury {
    minecraft = rootProject.minecraft_version
}

subprojects {
    apply plugin: "dev.architectury.loom"

    loom {
        silentMojangMappingsLicense()
    }

    dependencies {
        minecraft "com.mojang:minecraft:${rootProject.minecraft_version}"
        mappings loom.layered() {
            officialMojangMappings()
            parchment("org.parchmentmc.data:parchment-${rootProject.minecraft_version}:${rootProject.parchment_version}@zip")
        }
    }
}

allprojects {
    apply plugin: "java"
    apply plugin: "architectury-plugin"
    apply plugin: "maven-publish"

    base.archivesName = "${rootProject.archives_base_name}${StringUtils.capitalize(project.name)}"
    version = "${rootProject.mod_version}+mc.${rootProject.minecraft_version}"
    group = rootProject.maven_group

    repositories {
        mavenLocal()
        // Fix issue with lwjgl-freetype not being found on macOS
        maven {
            url = "https://libraries.minecraft.net"
            content {
                includeModule("org.lwjgl", "lwjgl-freetype")
            }
        }
        maven {
            name = "NeoForged"
            url = "https://maven.neoforged.net/releases"
        }
        maven {
            name = "RedlanceMinecraft"
            url = "https://repo.redlance.org/public"
        }
        maven {
            name = "Modrinth"
            url = "https://api.modrinth.com/maven"
            content {
                includeGroup "maven.modrinth"
            }
        }
    }

    tasks.withType(JavaCompile).configureEach {
        options.encoding = "UTF-8"
        options.release.set 21
    }

    jar {
        if (!rootProject.version.toString().contains("dev") && !project.gradle.startParameter.taskNames.contains("runClient"))
            processResources.exclude('assets/bendable_cuboids/player_animations/*')
    }

    java {
        withSourcesJar()
    }

    publishing {
        repositories {
            maven {
                name = "RedlanceMinecraft"
                url = "https://repo.redlance.org/public"
                credentials {
                    username = "dima_dencep"
                    password = System.getenv("MAVEN_PASSWORD")
                }
            }
        }
    }
}

tasks.register("publishToDiscord", PublishDiscordTask) {
    url.set(providers.environmentVariable("DISCORD_WEBHOOK"))
    username.set("BendableCuboids Updates")
    avatar.set("https://raw.githubusercontent.com/PlayerAnimationLibrary/BendableCuboids/refs/heads/main/common/src/main/resources/assets/bendable_cuboids/icon.png")

    container {
        it.title = "## ✨ ${rootProject.archives_base_name}\n### v${version} is out!"
        it.description = "### Changes:\n${rootProject.file("CHANGELOG.md").getText("UTF-8")}"

        it.thumbnail("https://raw.githubusercontent.com/PlayerAnimationLibrary/BendableCuboids/refs/heads/main/common/src/main/resources/assets/bendable_cuboids/icon.png")
        it.timestamp(System.currentTimeMillis())
    }

    links {
        it.fromEnvHack()
    }

    footer = "||<@&1411332102942752798>||"
}