elm-knobs/justfile at main · agj/elm-knobs · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
[private]
@default:
    just --list --unsorted

# Load a shell with all dependencies (if you don't use direnv).
init:
    @echo "You may type 'exit' to return to the regular shell.\n"
    nix develop -c "$SHELL"

# Preview the documentation.
[group("docs")]
docs:
    elm-doc-preview --port 8001 --no-browser

# Preview and develop the interactive documentation.
[group("docs")]
intdocs: intdocs-install
    cd interactive-docs && pnpm exec vite --clearScreen false

# Preview the interactive docs in full.
[group("docs")]
intdocs-full: install intdocs-build
    pnpm exec http-server ./interactive-docs/output/

# Update interactive doc example code.
[group("docs")]
intdocs-update-examples:
    nu ./scripts/update-example-code-strings.nu

# Build the interactive documentation.
[group("docs")]
intdocs-build: install intdocs-install intdocs-update-examples
    cd interactive-docs && pnpm exec vite build --outDir "./output/{{shell("nu ./scripts/get-current-version.nu")}}"
    nu ./scripts/build-examples.nu
    nu ./scripts/build-interactive-docs-index.nu

# Deploy interactive documentation to GH pages.
[group("docs")]
intdocs-deploy: intdocs-build
    pnpm install
    pnpm exec gh-pages --remote github --dist ./interactive-docs/output

# Updates the example code in the readme.
[group("docs")]
readme-update-example:
    nu ./scripts/update-readme-example.nu

[private]
intdocs-install:
    cd interactive-docs && pnpm install

[private]
install:
    pnpm install

# Run all checks and tests.
[group("checks")]
check: check-build test check-docs check-lint check-examples check-version

# Run tests.
[group("checks")]
test:
    elm-test

# Run tests and watch for changes.
[group("checks")]
test-watch:
    elm-test --watch

# Check for formatting errors.
[group("checks")]
check-lint:
    elm-format src --validate
    elm-review

# Automatically fix formatting errors.
[group("checks")]
check-lint-fix:
    elm-format src --yes
    elm-review --fix

# Suppress all remaining errors.
[group("checks")]
check-lint-suppress:
    elm-review suppress

# Check suppressed formatting errors.
[group("checks")]
check-lint-unsuppress:
    elm-review --unsuppress

# Make sure it compiles.
[group("checks")]
check-build:
    elm make --output /dev/null

# Make sure the examples compile.
[group("checks")]
check-examples:
    nu ./scripts/check-examples.nu

# Make sure the docs can be generated.
[group("checks")]
check-docs:
    elm-doc-preview --output /dev/null

# Make sure the package version is consistent across.
[group("checks")]
check-version:
    nu ./scripts/check-version.nu