Variable expansion

[andry81]

Both regular and delayed variable expansion has issues.

Tests

https://github.com/andry81/contools--debug/tree/HEAD/test_expand_regular_var.bat

@echo off

setlocal DISABLEDELAYEDEXPANSION

cd "%~dp0"

set "REM_ECHO=_externals\userbin\scripts\bat\rem-echo.bat"

set ?.=^^^<nul 2^^^>nul start /B /WAIT "" cmd.exe /c @start /WAIT "" cmd.exe /k @echo close me!

set ?.

echo ---

PROMPT=$S$H
echo on

@echo 1. exe cmdline expansion

"%COMSPEC%" /c @"%%REM_ECHO%%" %%?.%%

@echo ---

@echo 2. start+exe cmdline expansion with old environment

start /I /B /WAIT "" "%COMSPEC%" /c @"%REM_ECHO%" %%?.%%

@echo ---

@echo 3. call+script expansion

call "%%REM_ECHO%%" %%?.%%

@echo ---

@echo 4. script w/o call expansion

"%REM_ECHO%" %?.%

https://github.com/andry81/contools--debug/tree/HEAD/test_expand_delayed_var.bat

@echo off

setlocal DISABLEDELAYEDEXPANSION

cd "%~dp0"

set "REM_ECHO=_externals\userbin\scripts\bat\rem-echo.bat"

set ?.=^^^<nul 2^^^>nul start /B /WAIT "" cmd.exe /c @start /WAIT "" cmd.exe /k @echo close me!

set ?.

echo ---

setlocal ENABLEDELAYEDEXPANSION

PROMPT=$S$H
echo on

@echo 1. exe cmdline expansion

"!COMSPEC!" /c @"!REM_ECHO!" !?.!

@echo ---

@echo 2. start+exe cmdline expansion with old environment

start /I /B /WAIT "" "!COMSPEC!" /c @"!REM_ECHO!" !?.!

@echo ---

@echo 3. call+script expansion

call "!REM_ECHO!" !?.!

@echo ---

@echo 4. script w/o call expansion

"!REM_ECHO!" !?.!

https://github.com/andry81/userbin/tree/HEAD/scripts/bat/rem-echo.bat

@setlocal DISABLEDELAYEDEXPANSION DISABLEEXTENSIONS & (PROMPT=$S$H) & for %%z in (%%z) do rem |%*|

Results:

test_expand_regular_var.bat:

?.=^<nul 2^>nul start /B /WAIT "" cmd.exe /c @start /WAIT "" cmd.exe /k @echo close me!
---
1. exe cmdline expansion

"C:\WINDOWS\system32\cmd.exe" /c @"%REM_ECHO%" %?.%

rem |<nul 2>nul start /B /WAIT "" cmd.exe /c @start /WAIT "" cmd.exe /k @echo close me!|
---
2. start+exe cmdline expansion with old environment

start /I /B /WAIT "" "C:\WINDOWS\system32\cmd.exe" /c @"_externals\userbin\scripts\bat\rem-echo.bat" %?.%

rem |%?.%|
---
3. call+script expansion

call "%REM_ECHO%" %?.%

rem |<nul 2>nul start /B /WAIT "" cmd.exe /c @start /WAIT "" cmd.exe /k @echo close me!|
---
4. script w/o call expansion

"_externals\userbin\scripts\bat\rem-echo.bat" <nul 2>nul start /B /WAIT "" cmd.exe /c @start /WAIT "" cmd
.exe /k @echo close me!

rem |<nul 2>nul start /B /WAIT "" cmd.exe /c @start /WAIT "" cmd.exe /k @echo close me!|

test_expand_delayed_var.bat:

?.=^<nul 2^>nul start /B /WAIT "" cmd.exe /c @start /WAIT "" cmd.exe /k @echo close me!
---
1. exe cmdline expansion

"!COMSPEC!" /c @"!REM_ECHO!" !?.!

rem |<nul 2>nul start /B /WAIT "" cmd.exe /c @start /WAIT "" cmd.exe /k @echo close me!|
---
2. start+exe cmdline expansion with old environment

start /I /B /WAIT "" "!COMSPEC!" /c @"!REM_ECHO!" !?.!

rem |<nul 2>nul start /B /WAIT "" cmd.exe /c @start /WAIT "" cmd.exe /k @echo close me!|
---
3. call+script expansion

call "!REM_ECHO!" !?.!

rem |^ 2^ start /B /WAIT "" cmd.exe /c @start /WAIT "" cmd.exe /k @echo close me!|
---
4. script w/o call expansion

"!REM_ECHO!" !?.!

rem |^<nul 2^>nul start /B /WAIT "" cmd.exe /c @start /WAIT "" cmd.exe /k @echo close me!|

Note

1. Regular variable expansion does correct expansion in all cases, but requires to pass ?. variable into a child cmd.exe process command line (2d example with old environment reveals it).
2. Delayed variable expansion does correct expansion in an executable call command line, but not in a script call command line.