eclipse.inf

!% -~S
!% $OMIT_UNUSED_ROUTINES=1
!% $ZCODE_COMPACT_GLOBALS=1
!% $ZCODE_LESS_DICT_DATA=1
!% $ZCODE_MAX_INLINE_STRING=9999
!% $MAX_ABBREVS=96
!========================================
! Eclipse
! Morgan Tyler series #1 of 5
! Copyright © 2026 Gianluca Girelli
!========================================
!Constant DEBUG;

Abbreviate ". ";
Abbreviate ", ";
Abbreviate " the ";
Abbreviate "You";
Abbreviate "The";
Abbreviate "you";
Abbreviate "ing";
Abbreviate "It's";
Abbreviate "and";
Abbreviate "Thalos";
Abbreviate "'d better";
Abbreviate "Markus";
Abbreviate "with";
Abbreviate "tion";
Abbreviate ".^^";
Abbreviate "This";
Abbreviate " th";
Abbreviate " to";
Abbreviate " lo";
Abbreviate "e a";
Abbreviate "'s no";
Abbreviate " of";
Abbreviate " can";
Abbreviate " mo";
Abbreviate " in";
Abbreviate " wea";
Abbreviate " it";
Abbreviate " so";
Abbreviate "planet";
Abbreviate " start";
Abbreviate "r father";
Abbreviate " sh";
Abbreviate " co";
Abbreviate "lready";
Abbreviate "e n";
Abbreviate " di";
Abbreviate " is";
Abbreviate "d a";
Abbreviate " wa";
Abbreviate " hav";
Abbreviate "Earth";
Abbreviate "ent";
Abbreviate " from";
Abbreviate " ho";
Abbreviate " ba";
Abbreviate " esca";
Abbreviate " crystals";
Abbreviate " un";
Abbreviate " ma";
Abbreviate " don't";
Abbreviate " wo";
Abbreviate " ex";
Abbreviate " on";
Abbreviate "here";
Abbreviate " no";
Abbreviate " do";
Abbreviate "s a";
Abbreviate " st";
Abbreviate " ca";
Abbreviate " ne";
Abbreviate "n't";
Abbreviate " de";
Abbreviate "hat";
Abbreviate " be";
Abbreviate "ward";
Abbreviate " se";
Abbreviate "und";
Abbreviate " re";
Abbreviate "ver";
Abbreviate " for";
Abbreviate "Fhenor";
Abbreviate "ship";
Abbreviate " happe";
Abbreviate "ine";
Abbreviate "water";
Abbreviate "int";
Abbreviate " fa";
Abbreviate " frie";
Abbreviate "s lik";
Abbreviate "first";
Abbreviate " la";
Abbreviate " we";
Abbreviate " might";
Abbreviate "sout";
Abbreviate "xoskeleto";
Abbreviate " ro";
Abbreviate " helmet";
Abbreviate " pressure suit";
Abbreviate " power";
Abbreviate "_to/";
Abbreviate " me";
Abbreviate " take";
Abbreviate " rifle";
Abbreviate " plac";
Abbreviate " spec";
Abbreviate "ble";

Constant Story "Eclipse";
Constant Headline "^Morgan Tyler series #1 of 5^Copyright (c) 2026 Gianluca Girelli^https://bdb-project.itch.io^Type ABOUT for further info and credits.^^";

Array UUID_ARRAY string "UUID://39972ae0-6e6e-4fcb-8881-ff1e3668976b//";
#Ifdef UUID_ARRAY;
#Endif;

Release 1;
Serial "260606";

!Inform 6 constants
Constant DEATH_MENTION_UNDO;
Constant MAX_CARRIED = 8;
Constant NO_SCORE;

!PunyInform constants
Constant CUSTOM_ABBREVIATIONS;
Constant OPTIONAL_EXTENDED_METAVERBS;
Constant OPTIONAL_EXTENDED_VERBSET;
Constant OPTIONAL_FULL_DIRECTIONS;
Constant OPTIONAL_PRINT_SCENERY_CONTENTS;
Constant OPTIONAL_PROVIDE_UNDO;
Constant RUNTIME_ERRORS 0;!0 for release, 2 for debug

!PunyInform static messages
Constant MSG_COMMENT_NO_TRANSCRIPT "Comment recorded. Use SCRIPT ON to save future comments in a transcript.^";
Constant MSG_COMMENT_TRANSCRIPT "Comment recorded.^";
Constant MSG_PARSER_NO_INPUT "You need to enter a command.";
Constant MSG_PARSER_UNKNOWN_VERB "That's not a verb I recognise.";
Constant MSG_SORRY_DEFAULT "Oh, don't apologise.";
Constant MSG_WAIT_DEFAULT "Time passes...";

!PunyInform dynamic messages
Constant MSG_CLOSE_NOT_OPEN 1000;
Constant MSG_LOCK_ALREADY_LOCKED 1001;
Constant MSG_LOCK_CLOSE_FIRST 1002;
Constant MSG_LOCK_KEY_DOESNT_FIT 1003;
Constant MSG_UNLOCK_ALREADY_UNLOCKED 1004;
Constant MSG_UNLOCK_KEY_DOESNT_FIT 1005;

!Game-specific constants
Constant CANT_TAKE_VEHICLE_THAT_WAY "You can't take the pod that way. You'll have to leave it behind, unless you have a way to lift it.";
Constant CANT_SHOOT_ANYTHING_WITH "You can't shoot anything with ";

!Replaced actions
Replace _UpdateDarkness;
Replace GoSub; !Delete if diagonal directions are used
Replace LockSub;
Replace UnlockSub;

Include "globals.h";

!Game-specific variables
Attribute passable;   !can be traversed with the pod

!========================================
! Entry point routines
!========================================
[ LibraryMessages p_msg p_arg_1 p_arg_2;
  switch (p_msg)
  {
    MSG_CLOSE_NOT_OPEN:
      print_ret (CTheyreOrIts)noun, " already closed.";
    MSG_LOCK_ALREADY_LOCKED:
      print_ret (CTheyreOrIts)noun, " already locked.";
    MSG_LOCK_CLOSE_FIRST:
      "You'll have to close ", (ItOrThem)noun, " first.";
    MSG_LOCK_KEY_DOESNT_FIT:
      print_ret (The)second, " ", (DoesntOrDont)second, " fit the lock.";
    MSG_UNLOCK_ALREADY_UNLOCKED:
      print_ret (CTheyreOrIts)noun, " already unlocked.";
    MSG_UNLOCK_KEY_DOESNT_FIT:
      print_ret (The)second, " ", (DoesntOrDont)second, " fit the lock.";
  }
  p_arg_1 = p_arg_2;
];

Include "puny.h";

!========================================
! Initialisation
!========================================
[ Initialise;
  location = room31;
  lookmode = 2;
  no_implicit_actions = true;
  player.description = PlayerDescription;
  "With the advent of interstellar travel, Earth settlers reached the planet Thalos, where they built Thalos City. At first, the colony lived in peace, with some of the settlers (including your father and his best friend, Markus) trying to blend in with the natives.^^Once your father and Markus had befriended the natives, they learned that they were actually ancient cosmic alchemists, with a peculiar understanding of the universe. This included a phenomenon that they called the 'eclipse'. The eclipse occurs every fifteen years and blocks communications with Earth, but this knowledge had been kept hidden from the settlers. To most settlers, the Thalos natives appeared as simple people with moderate technological capabilities, and nothing more.^^Fhenor Darkscepter was initially the Governor of Thalos and represented the Earth's Government. Towards the end of the colonisation phase, Darkscepter rose to power, became a dictator, and took full control of the city and, subsequently, the planet. This was possible thanks to information censorship and the brainwashing of any opponents. Brainwashing was not imposed on the alchemists, as they were outside the circle of power and were considered harmless.^^Determined to fight Fhenor's dictatorship, your father and Markus, together with a few alchemists, developed a plan to escape Thalos and return to Earth to reveal what's really been happening on Thalos. One night, during the eclipse, Markus boarded a small spaceship and departed towards Earth to seek help. All contact was lost soon after take off, but that was to be expected because of the eclipse. As no help ever arrived from Earth, it was assumed that Markus never made it.^^These events took place fifteen years ago. The next eclipse is due soon and it's now your turn to try reaching Earth in search of help. It's time to say goodbye to your father and board the spaceship.^";
];
  
!========================================
! Room 31: Living room
!========================================
Object room31 "Living Room in Your House"
with
  description 
  [;
    "The living room you're in is warm and comfy. It has the peculiar look that blends architectural elements coming both from Earth and Thalos. The furniture is nothing eccentric, the only noticeable feature being a cupboard with a framed picture on it. The only exit is south.";
  ],
  s_to
  [;
    if (room31 hasnt general)
      "You should talk to your father, first.";
    give self general;
    if (father in location)
    {
      move father to room32;
      print"Your father follows you.^^";
    }
    return room32;
  ],
has light;

!----------------------------------------
! Room
!----------------------------------------
Object "room" room31
with
  name 'living' 'room' 'furniture',
  description "There's nothing special about the room or the furniture.",
has scenery;

!----------------------------------------
! Cupboard
!----------------------------------------
Object "cupboard" room31
with
  name 'cupboard', 
  description "It's a fine crafted cupboard, but at present you are not interested in it.",
  before
  [;
    Open, Close, Search:
      "You don't need to bother with it.";
    Take, Push, Pull:
      "There's nothing to take, push or pull.";
  ],
has scenery;

!----------------------------------------
! Framed Picture
!----------------------------------------
Object picture "framed picture" room31
with
  name 'framed' 'picture', 
  description "The picture was taken fifteen years ago, but you feel like a century has passed by. In the picture, taken when you were 10, your father stands between you and his best friend, Markus. Markus was already in his spacesuit before boarding his ship. He was almost an uncle to you, and you have been missing him ever since.",
  before
  [;
    Take:
      "It's the only picture left of your father's best friend. Please leave it there.";
  ]
has scenery;

!----------------------------------------
! Morgan's Father
!----------------------------------------
Object father "father" room31 
with
  article "your",
  name 'father' 'old' 'man' 'dad',
  description
  [;
    print"Your father stands near you with a sad look on his face. He probably senses that he might not see you for a long time, or never again if things go wrong. ";
    if ((self in room31) && (room31 hasnt general))
      "You should try talking to him.";
    if ((self in room32) && (room32 hasnt general))
      "It's almost time for you to leave. It's probably your last chance to talk to him for a while.";
    "";   
  ],
  life
  [;
    Ask:
      wn = consult_from;
      switch (NextWord())
      {
        'escape':
          "~Yes, it's time to go. Or were you referring to the pod? I wasn't paying attention.~";
        'framed', 'picture':
          if (picture hasnt general)
          {
            give picture general;
            "~We took it the night he left in search for help. Now, my son, it's your turn to try.~";
          }
          else
            "~I already told you about the picture.~";
        'friend', 'markus':
          "~He was like a brother to me, and an uncle to you. Wherever he is now, I hope he's fine.~";
        'pod':
          "~Let's hope you won't need it, but it's very efficient and can also float on water.";
        'ship', 'spaceship':
          "~It's the fastest in the galaxy. She made the Kessel Run in less than 12 parsecs. But that was in a galaxy far, far away.~";
        default:
          "~This is no time for questions, Morgan. There's work to be done.~";
      }
    Kiss: !-> hug
      "You hug your father and, for a moment, the weight of the endeavour you are about to start seems to get lighter.^^~Enough hugging, son.~ you hear your father saying. ~You have work to do.~";
    Talk:
      if ((self in room31) && (room31 hasnt general))
      {
        give room31 general;
        "~Morgan, the 'planetary eclipse' is about to start. It will soon cause severe malfunctioning in the communications and control systems. Despite the name, the 'eclipse' is not a phenomenon related to light but to electromagnetic signals and, acting like a jamming device, it will allow you to escape from Thalos undetected by Fhenor's minions. It occurs every fifteen years and it's still unknown to Fhenor, although he might be close to discovering how Markus escaped. We need to exploit it before it's too late. Please make haste.~";
      } 
      if ((self in room32) && (room32 hasnt general))
      {
        give room32 general;
        "~My son, it's time for you to leave. Thalos has fallen, and no help will come unless we go and try to bring it ourselves.~^^Your father stops talking for a moment, then he resumes.^^~This could be your last chance to escape. Fhenor's troopers are always around patrolling the streets, and they could come here just as part of their ordinary routine. If this happens, we'll be doomed forever.~^^Your father looks at you, straight into your eyes, showing all the love a father can have for his son. Then, he talks to you once again.^^~Your ship is small, yet fully capable of withstanding the journey. Should anything go wrong, just remember there is a rifle inside the cockpit for your self-defense. Also, the ship is equipped with an escape pod that can also float on water. I hope you won't have to use it.~";
      }
      if (self in room33)
        "~Enough talking, my son. Your time has come. Take off and make Thalos proud of you.~";    
      "~We should proceed, now.~";
  ],
  before
  [;
    Shoot:
      if (CantBeShot())
        rtrue;
      "You mimic the gesture of shooting your father, like you did when you were a kid, to say that you loved him. You both laugh, then seriousness takes place again.";
  ],
has animate;

!========================================
! Room 32: Back of House
!========================================
Object room32 "Back of House"
with
  description 
  [;
    "There's nothing significant here, only a wide empty space. From here you can either go back north towards the house, or continue south.";
  ],
  n_to room31,
  s_to
  [;
    if (room32 hasnt general)
      "Soon you will leave Thalos, so you might want to talk to your father one more time.";
    give self general;
    if (father in location)
    {
      move father to room33;
      print"Your father follows along.^^";
    }
    return room33;
  ],
has light;

!----------------------------------------
! Back of House
!----------------------------------------
Object "back of house" room32
with
  name 'back' 'of' 'house' 'farm' 'house' 'wide' 'empty' 'space',
  description "The back of the house doesn't reveal anyting of interest. It's just an empty space that opens towards the south.",
has scenery;

!========================================
! Room 33: Shipyard
!========================================
Object room33 "Shipyard"
with
  description 
  [;
    "Disguised among heaps of junk you can see the ship that your father has prepared for you to escape Thalos. It's actually rather small, able to accommodate only two or three people as crew. Yet, she will have to do. From here, you can go back north towards the back of the house or enter the ship.";
  ],
  n_to room32,
  in_to
  [;
    <<Enter ship>>;
  ],
has light;

!----------------------------------------
! Heaps of junk
!----------------------------------------
Object "heaps of junk" room33
with
  article "some",
  name 'heaps' 'of' 'junk' 'heap',
  description "In part those heaps are real junk, but they mostly serve to hide the spaceship.",
  before
  [;
    Search:
      "Nope, nothing but junk.";
  ],
has scenery;

!----------------------------------------
! Ship (floating object)
!----------------------------------------
Object ship "ship"
with
  article "your",
  name 'ship' 'spaceship',
  description "It looks compact, robust, and fast. You hope it's true and not just your impression.",
  before
  [;
    Enter:
      if (self in room33)
      {
        print"^You enter the ship, sit down in the cockpit and initiate the start-up sequence. Before you finish feeding the mission computer with all the necessary data, your peripheral vision catches Fhenor's agents entering the shipyard and confronting your father.^^He tries to stop them, but they open fire on him, and you see him falling to the ground. With death in your heart and tears in your eyes, you go full-throttle and leave the place.^^Soon after gaining the upper orbit the eclipse starts, and your navigation system loses track of your route right when you entered the wormhole towards Earth. When you get out of it, the ship starts shaking, and gets attracted by the gravity of an unknown planet that doesn't look like Earth should. With the ship collapsing and tearing apart, you just manage to enter the escape pod and bail out.^^Your journey is interrupted.^^";
        give ship general;
        move remote to player;
       PlayerTo(pod1, 2);
        rtrue;
      }
    Exit:
      if (self in room34)
        <<Go FAKE_OUT_OBJ>>;
  ],
  found_in room33 room34,
has static;

!========================================
! Room 34: The Ship
!========================================
Object room34 "Ship"
with
  description 
  [;
    "This is the interior of your ship.";
  ],
  out_to room33,
has light;

!========================================
! Room 1: Inside Escape Pod
!========================================
! removed from the game

!========================================
! Room 2: Surface of Planet
!========================================
Object room02 "Surface of Planet"
with
  description 
  [;
    if (button hasnt general)
      "The inside of the pod is so narrow that you can barely move. Under the hot atmosphere of the planet, it really leaves much to be desired as a place to linger. Inside it, you are suffocating and sweating profusely. You need to get out.";  
    "Nothing but a monotonous expanse of rocks of various sizes can be seen. On the ground, there's nothing but reddish sand. The only direction is north.";
  ],
  n_to room03,
has light;

!----------------------------------------
! Single-button remote control
!----------------------------------------
Object remote "single-button remote control"
with
  name 'single-button' 'remote' 'control',
  description "This weird remote is used to open and close the escape pod. It doesn't make much sense, but this is how things work here. The remote has a single button.",
  before
  [;
    Push:
      <<Push button>>;
  ],
  add_to_scope button,
has;

!----------------------------------------
! Button on remote control
!----------------------------------------
Object button "button" 
with
  name 'button',
  description "It's exactly what it looks like: a button.",
  before
  [;
    Push:
      if (self hasnt general)
      {
        give self general;
        give pod1 open;
        move canopy to room02;
        "As soon as you push the button on the remote control, tiny microcharges burst with a loud noise, jettisoning the canopy. A wave of heat from the planet's rarefied atmosphere hits you, and your breathing gets heavy. You can now exit the pod.";
      }
      "You already pushed the button, and the pod is now open.";
  ],
has scenery;

!----------------------------------------
! Pod Canopy
!----------------------------------------
Object canopy "canopy"
with 
  article "the",
  name 'canopy',
  description
    "It's the canopy you just jettisoned to open the pod.",
  before
  [;
    Take:
      "You have no use for it.";
  ],
has static;

!----------------------------------------
! Surface of planet (floating object)
!----------------------------------------
Object "surface of planet"
with
  name 'monotonous' 'expanse' 'of' 'rocks' 'surface' 'planet',
  description "Seen from here, the planet looks truly inhospitable. Wherever you turn your gaze, you only see rocks and sand.",
  found_in room02 room03,
has scenery;

!----------------------------------------
! Sand
!----------------------------------------
Object "sand" room02
with
  name 'sand',
  description "It's just sand, and covers most of the planet, it seems.",
  before
  [;
    Search:
      "Don't bother with it. Besides, it covers most of the planet, so it would be impossible for you to search everywhere.";
    Take:
      "You try to take the sand but it slips through your hands. Don't worry about it.";
  ],
has scenery;

!----------------------------------------
! Escape pod
!----------------------------------------
Object pod1 "escape pod" room02
with
  article "your",
  name 'escape' 'pod',
  invent
  [;
    if (inventory_stage == 2 && child(self) == 0)
      rtrue;
  ],
  description
  [;
    print"The pod allowed you to survive the crash and land safely on this alien planet.";
    if (button hasnt general)
      " It's very hot inside it, so you should get out.";
    print" Despite the crash landing, it's still in good shape and can even float on water";
    if (pod1 hasnt general)
    {
      if (exoskeleton hasnt worn)
       " should you find a way to take it with you.";
      else 
        ". When you are wearing the exoskeleton you are able to take it with you around.";
    }
  ],
  react_before
  [;
    if (player notin self)
      rfalse;
    if (noun == nothing)
      rfalse;
    if (action == ##Examine or ##Go or ##Shoot or ##Push)
      rfalse;
    if (CommonAncestor(parent(player), noun) ~= self)
      "You can't reach ", (the)noun, " while you're in the pod.";
    Insert, PutOn:
      if (CommonAncestor(parent(player), second) ~= self)
        "You can't reach ", (the)second, " while you're in the pod.";
  ],
  before
  [ destination;
    Go:
      destination = location.(direction_properties_array->selected_direction_index);
      if (destination ofclass Object)
      {
        if (destination has door || destination hasnt passable)
        {
          print (string)CANT_TAKE_VEHICLE_THAT_WAY, "^";
          return 2;
        }
      }
      if ((location == room13) || (location == room12))
      {
        if (pole notin player)
        {
          print"Although the pod can be used as a life raft, you need something to thrust yourself through the shallow waters of the basin. Have you found anything suitable for the task?^";
          return 2;
        }
      }
      return 1;
    Open: 
      if (button hasnt general)
        "You can't. It's hermetically sealed.";
      else
        "The pod is already open.";
    Close:
      if (button hasnt general)
        "The pod is already sealed.";
      "You can't close the pod, now that you jettisoned its canopy.";
    Exit:
      if (button hasnt general)
        "You should find a way to open the pod, first.";
      if (helmet hasnt worn)
        StartDaemon(suit);
    Insert:
      if ((location == room12) || (location == room13))
        "Maybe you could try pushing it into the water.";
      "The pod is too big to fit into it.";
    Push:
      if ((player in room13) || (player in room12))
      {
        if (helmet hasnt worn)
          "Be sure to wear your helmet before going to an area where the air might not be breathable.";
        if (pole notin player)
          "Although the pod can be used as a life raft, you need something to thrust yourself through the shallow waters of the basin. Have you found anything suitable for the task?";
        if (player in room13)
          move pod1 to room18;
        else
          move pod1 to room17;
        move player to pod1;
        print"You push the pod towards the basin, and climb into it before getting in touch with the acidic water. You are now using the pod as a raft.^^";
        <<Go FAKE_W_OBJ>>;
      }
    Take:
      if (room23 has visited)
        "As it's covered in acid, you cannot take it any more. You can still push into the basin if you need to navigate its waters.";
      if (player in self)
        "You can't take the pod while you're inside it.";
      if (exoskeleton hasnt worn)
        "You're not strong enough to carry the escape pod.";
      if (self notin player)
      {
        move self to player;
        "The strength given you by the exoskeleton allows you to take and carry the pod.";
      }
      "You already have the pod.";
  ],
  after
  [;
    Enter:
      "You get in the pod.";
    Exit, GetOff:
      if ((location == room17) || (location == room18))
      {
        deadflag = 1;
        "You thrust yourself out of the pod, and fall into the deadly waters of the basin. In a few seconds, the acid dissolves your body. Thalos is now doomed.";
      }
      "You exit the pod.";
  ],
has enterable static container openable transparent; !open;

!========================================
! Room 3: Long Channel (south)
!========================================
Object room03 "Southern Part of Long Channel"
with
  description "A very long channel with steep walls extends to the north, disappearing in the distance in the hazy atmosphere of the planet.",
  n_to room04,
  s_to room02,
has light;

!----------------------------------------
! Long channel (floating object)
!----------------------------------------
Object "channel"
with
  name 'very' 'long' 'channel' 'steep' 'walls' 'rocks',
  description "There's not much more to see here but rocks.",
  found_in room03 room04,
has scenery;

!----------------------------------------
! Hazy atmosphere (floating object)
!----------------------------------------
Object "hazy atmosphere" 
with
  name 'hazy' 'atmosphere' 'air',
  description "The combined effect of the heat and fine sand suspended midair hampers your vision and makes it difficult to estimate distances.",
  found_in room03 room04,
has scenery;

!========================================
! Room 4: Long Channel (north)
!========================================
Object room04 "Northern Part of Long Channel"
with
  description "A very long channel with steep walls extends to the south, disappearing in the distance in the hazy atmosphere of the planet. From this position you can also go up to climb out of the channel.",
  s_to room03,
  u_to room06,
has light;

!========================================
! Room 5: Surface of Planet
!========================================
Object room05 "Surface of Planet"
with
  description "The surface of the planet becomes very rocky at this point, and sparse debris covers it becoming more numerous towards the west. To the north, you can see the edge of the channel from which you emerged, while to the south, a true deserted territory opens up.",
  n_to room06,
  s_to room20,
  w_to room09,
has light;

!----------------------------------------
! Surface of planet (floating object)
!----------------------------------------
Object "surface of the planet"
with
  name 'surface' 'of' 'the' 'planet' 'rocks' 'debris',
  description "It's just rocks, sand and debris. Who could live in such a place?",
  found_in room05 room08,
has scenery;

!========================================
! Room 6: Edge of Channel
!========================================
Object room06 "Edge of Channel"
with
  description "You're on the edge that leads to your escape pod. Towards the north, the territory transforms into an arid expanse of gravel and, to the south, it's just covered with rocks. You can also go down towards the channel you came from.",
  n_to room21,
  s_to room05,
  d_to room04,
has light;

!----------------------------------------
! Edge of channel (floating object)
!----------------------------------------
Object "channel" room06
with
  name 'edge' 'of' 'channel',
  description
  [;
    if (location == room05)
      "Even if you are now on high terrain, there's not much to be seen. The view is bleak.";
    "The edge of the channel is the highest point on this side of the planet.";
  ],
  found_in room05 room06 room21,
has scenery;

!========================================
! Room 7: In Front of Strange Construction
!========================================
Object room07 "In Front of Strange Construction"
with
  description "Towards the south stands a strange construction with a familiar and typically terrestrial appearance. To the west, the strip of emerged surface dives back into the deadly waters of the planet.",
  w_to room12,
  s_to room23,
  in_to room23,
has light;

!----------------------------------------
! Strange construction
!----------------------------------------
Object "strange construction"
with
  name 'strange' 'construction' 'house',
  description "It resembles a typical terrestrial house.",
  before
  [;
    Enter:
      if (self in room07)
        <<Go FAKE_IN_OBJ>>;
    Exit:
      if (self in room23)
        <<Go FAKE_OUT_OBJ>>;
  ],
  found_in room07 room23,
has scenery;

!========================================
! Room 8: Surface of Planet
!========================================
Object room08 "Surface of Planet"
with
  description "A fine reddish sand, similar to the one you saw at the bottom of the channel, covers the vast area of the planet's surface on which you now stand. The scattered remains of your ship can be seen all around. From here you can either go north or west.",
  n_to room09,
  w_to room13,
has light;

!----------------------------------------
! Long expanse of sand (floating object)
!----------------------------------------
Object "sand"
with
  name 'long' 'expanse' 'of' 'reddish' 'sand',
  description "The sand has a reddish tinge, probably due to the presence of iron oxide.",
  found_in room05 room08 room13,
has scenery;

!----------------------------------------
! Remains of your ship's engine
!----------------------------------------
Object engine "remains of your ship" room08
with
  article "the",
  name 'scattered' 'remains' 'of' 'your' 'ship' 'engine',
  description "The most noticeable thing is the engine. The technology behind it is fascinating, but it's totally useless now that the engine, its central housing and its fairings have been turned into a heap of junk.",
  before
  [;
    Search:
      <<Search junk>>;
  ],
has static;

!----------------------------------------
! Junk
!----------------------------------------
Object junk "junk" room08
with
  article "the",
  name 'heap' 'of' 'junk' 'central' 'housing' 'fairings',
  description
  [;
	  print "After the crash, what remains of the engine is just junk. ";
		if (self hasnt general)
		  "Yet, it might be worth searching through it.";
		else
		  "You've already searched through the junk, so it's not worth searching it again.";
	],
  before
	[;
	  Search:
			print "You search through the junk";
			if (self hasnt general)
			{
		    give self general;
        move rod to room08;
        move pole to room08;
				" and find a solium rod and a metal pole.";
			}
			", but don't find anything else of interest.";
  ],
has scenery;

!----------------------------------------
! Solium rod
!----------------------------------------
Object rod "solium rod"
with
  name 'solium' 'rod',
  description "It's a rod made of a mineral called 'solium'. It can power a photon rifle.",
  before
  [;
    Insert:
      if (second == rifle)
        <<Load second self>>;
  ],
has;

!----------------------------------------
! Very light metal pole
!----------------------------------------
Object pole "very light metal pole"
with
  name 'very' 'light' 'metal' 'pole',
  description
    [;
      if (room13 hasnt visited)
        "You have no clue what it's for, but it's very long.";
      "The metal pole can be used as an oar to direct the pod across the shallow waters of the basin.";
    ],
has;

!========================================
! Room 9: Vast Rocky Terrain
!========================================
Object room09 "Vast Rocky Terrain"
with
  description "This is a vast rocky terrain, on which debris of unknown origin lies, extending into the distance before your eyes. From here you can proceed north, south or east.",
  n_to room10,
  s_to room08,
  e_to room05,
has light;

!----------------------------------------
! Vast rocky terrain (floating object)
!----------------------------------------
Object "rocky terrain"
with
  name 'vast' 'rocky' 'terrain' 'rocks' 'debris' 'rock' 'fragments',
  description "The terrain is really impervious and rocks and debris make walking difficult.",
  found_in room09 room10,
has scenery;

!----------------------------------------
! Part of your ship's cockpit
!----------------------------------------
Object cockpit "remains of your ship's cockpit" room09
with
  article "the",
  name 'remains' 'of' 'your' 'ship^s' 'cockpit' 'mess',
  description
  [;
	  print "After the crash, what remains of the cockpit is a total mess and nothing seems usable any more. ";
		if (rifle in nothing)
		  "Yet, it might be worth searching through it.";
		else
		  "You've already searched through the mess, so it's not worth searching it again.";
	],
  before
	[;
	  Search:
			print "You search through the mess";
			if (rifle in nothing)
			{
		    move rifle to room09;
				" and find your photon rifle.";
			}
			", but don't find anything of interest.";
  ],
has static;

!----------------------------------------
! Photon rifle
!----------------------------------------
Object rifle "photon rifle"
with
  article "your",
  name 'photon' 'rifle' 'gun' 'weapon',
  description
  [;
    print "It's a photon rifle, part of the standard equipment of a starship and used for self-defense purposes. It's ";
    if (rod hasnt general)
      "not currently loaded.";
    "fully charged, and ready to fire.";
  ],
  before
  [;
    Drop, Insert:
      "This is a deadly place. You'd better keep your rifle with you.";
    Load:
      if (rod has general)
      {
       "It's already loaded and fully charged.";
      }
      if (second == nothing && rod in player)
      {
        print "(with the solium rod)^";
        second = rod;
      }
      if (second == nothing)
        "You don't have anything suitable to load it with.";
      if (second ~= rod)
        "You can't load the rifle with ", (ThatOrThose)second, ".";
      give rod general;
      move rod to limbo;
      "You load the rifle with the solium rod.";
  ],
has;

!========================================
! Room 10: Vast Rocky Terrain
!========================================
Object room10 "Vast Rocky Terrain"
with
  description "This is a long strip of land leading north to the mouth of a large crater. It's scattered with a large number of rock fragments of all sizes that continue to the south.",
  n_to room11,
  s_to room09,
has light;

!========================================
! Room 11: Edge of Crater
!========================================
Object room11 "Edge of Crater"
with
  description "You've reached the edge of a large crater formed by a meteorite. A steep slope leads to the bottom. You can either go down into the crater or south, back to where you came from.",
  s_to room10,
  d_to room16,
has light;

!----------------------------------------
! Crater (floating object)
!----------------------------------------
Object "crater"
with
  name 'mouth' 'edge' 'of' 'large' 'crater',
  description "The crater is very wide, a sign of a tremendous impact that happened who knows when.",
  found_in room10 room11 room16,
has scenery;

!========================================
! Room 12: Shore of Island
!========================================
Object room12 "Shore of Island"
with
  description "You've reached the shore of a tiny island consisting of a narrow strip of volcanic material, probably emerged due to an ancient eruption. To the west, you can see the basin of water you just crossed with the pod. The shore expands a little bit towards the east.",
  n_to "There's no point in going north.",
  s_to "There's no point in going south.",
  e_to room07,
  w_to
  [;
    if (helmet hasnt worn)
          "The air is barely breathable in that direction. You'd better wear your helmet before going west.";
    if (player notin pod1)
        "If you intend to cross the basin you'd better enter the pod first.";
    else
      return room17;
  ],
  before
  [;
    Hint:
      if (pod1 notin self)
        "Your pod was design to stay afloat, in case it ended up on water.";
      "Have you examined your pod?";
    Swim:
      deadflag = 1;
      print"You enter the river and try to swim to the opposite bank, but the water in the basin is full of highly acidic substances. ";
      if (suit hasnt worn)
        "Their corrosive power is fatal. ";
      else 
        print"At first, your pressure suit seems to resist and, for a brief moment, you think you might escape this trap. Soon, though, it starts melting. ";
      "It's over for you.";
  ],
has passable light;

!----------------------------------------
! Shore
!----------------------------------------
Object "shore" room12
with
  name 'shore' 'tiny' 'strip' 'of' 'volcanic' 'material',
  description "The dark color of the sand indicates its volcanic origin. There's nothing special about it.",
has scenery;

!----------------------------------------
! Island
!----------------------------------------
Object "island" room12
with
  name 'tiny' 'island',
  description "At a first analysis, what is now an island used to be a peninsula until not long ago. A stone bridge, now collapsed, used to connect this portion of land to the mainland behind it.",
has scenery;

!----------------------------------------
! Stone bridge
!----------------------------------------
Object "bridge" room12
with
  name 'collapsed' 'stone' 'bridge' 'mainland',
  description "A collapsed natural stone bridge, possibly created by the erosion of the winds, used to connect this portion of land to the mainland. You don't see any exits from this location.",
has scenery;

!========================================
! Room 13: Long Expanse of Sand
!========================================
Object room13 "Long Expanse of Sand"
with
  description "You've arrived right in the middle of a long and thin expanse of sand. It's bordered to the west with a water basin and to the east by the scattered remains of the spaceship where you crashed.",
  n_to "There's no point in going north.",
  s_to "There's no point in going south.",
  e_to room08,
  w_to
  [;
    if (player notin pod1)
        "If you intend to cross the basin you'd better use something to stay afloat.";
    else
      return room18;
  ],
  before
  [;
    Hint:
      if (pod1 notin self)
        "Your pod was design to stay afloat, in case it ended up on water.";
      if ((pod1 in self) && (pole notin player))
        "You need something long enough to be used as an oar to propel the pod in the water.";
      "Have you examined the pod or the metal pole?";
    Swim:
      deadflag = 1;
      print"You enter the river and try to swim to the opposite bank, but the water in the basin is full of highly acidic substances. ";
      if (suit hasnt worn)
        "Their corrosive power is fatal. ";
      else 
        print"At first, your pressure suit seems to resist and, for a brief moment, you think you might escape this trap. Soon, though, it starts melting. ";
      "It's over for you.";
  ],
has passable light;

!----------------------------------------
! Water (floating object)
!----------------------------------------
Object water "water"
with
  name 'water',
  description "You are not sure how pure that water could be, or if it contains acidic, possibly corrosive, substances. You'd better stay away from it.",
  before
  [;
    Drink:
      print"Dude, no!";
      if ((real_location == room12) || (real_location == room13))
        print" You're too far away to reach it!";
      "";
    Enter:
      <<Swim>>;
  ],
  found_in room12 room13 room17 room18,
has scenery;

!========================================
! Room 14: Large Underground Room
!========================================
Object room14 "Large Underground Room"
with
  description "The large underground room hidden beneath the crater is lit by numerous blue crystals that glow with a phosphorescent light. Above you, very high up, you can see the opening from which you fell. A long tunnel runs towards the west.",
  w_to
  [;
    if (aliens hasnt general)
    {
      aliens.time_left = 0;
      StartDaemon(aliens);
    }
    return room24;
  ],
  before
  [;
    Go:
      if (selected_direction == out_to || selected_direction == u_to)
      {
        if (helmet hasnt worn)
          "The air is barely breathable up there. You'd better wear your helmet before going up.";
        if (exoskeleton has worn)
        {
          print"With a very strong push of your legs you easily reach the opening, surprised by your strength and agility.^^";
          PlayerTo(room19);
          rtrue;
        }
        "The exit is too far above to be reached. For the time being you are trapped down here.";
      } 
    Jump:
      if (helmet hasnt worn)
        "The air is barely breathable up there. You'd better wear your helmet before going up.";
      if (exoskeleton has worn)
      {
        print"With a very strong push of your legs you easily reach the opening, surprised by your strength and agility.^^";
        PlayerTo(room19);
        rtrue;
      }
    "You throw yourself with all your strength towards the hole, but you realise that it is too far away for you to reach it with a jump.";
  ],
has light;

!----------------------------------------
! Underground room
!----------------------------------------
Object "underground room" room14
with
  name 'large' 'underground' 'room' 'mining' 'area' 'debris',
  description "This large underground room looks like a sort of mining area, with debris scattered everywhere.",
has scenery;

!----------------------------------------
! Long tunnel
!----------------------------------------
Object "tunnel"
with
  name 'long' 'tunnel',
  description
  [;
    print"It's a long, dark tunnel running ";
    if (location == room14)
      "towards the west.";
    "east to west.";  
  ],
  found_in room14 room24,
has scenery;

!----------------------------------------
! Blue crystals
!----------------------------------------
Object crystals "blue crystals" room14
with
  name 'blue' 'xelon' 'crystals' 'crystal',
  description "These crystals looks like 'xelon', a mineral used as the base technology for warp engines. They may prove useful.",
  before
  [;
    Drop:
      "You'd better not. You don't know when you might need'em.";
    Take:
      if (exoskeleton hasnt worn)
        "You try to collect the crystals but you discover, with amazement, that they weigh much more than you thought in relation to their size. After several attempts, you give up trying.";
      if ((crystals in player) && (location == room14))
        "You already have more than enough crystals.";
      if (crystals notin player)
      {
        move crystals to player;
        if (location == room14)
          "Thanks to the exoskeleton you are wearing, you are now able to lift the crystals without any difficulty. You take a handful of them and put them in your inventory.";
        "Taken.";
      }
      else
        "You already have the crystals.";
  ],
has pluralname;

!========================================
! Room 15: Bottom of Crater
!========================================
Object room15 "Bottom of Crater"
with
  description "You've reached the bottom of the vast and desolate meteorite crater. Around you, you can see the steep slope that leads up, out of it. To the west, the crater becomes more impervious.",
  w_to room19,
  u_to room16,
has light;

!----------------------------------------
! Crater (floating object)
!----------------------------------------
Object "crater"
with
  name 'bottom' 'of' 'vast' 'desolate' 'meteorite' 'crater',
  description "The crater looks very ancient. The meteorite that caused it must have fallen a long time ago.",
  found_in room15 room19,
has scenery;

!========================================
! Room 16: Steep Slope into Crater
!========================================
Object room16 "Steep Slope into Crater"
with
  description "The steep slope that leads to the crater floor is composed of very friable soil that crumbles under the weight of your body, making every movement difficult. Above you, you can see the edge of the crater. From here you can either go up or down.",
  u_to room11,
  d_to room15,
has light;

!----------------------------------------
! Steep slope (floating object)
!----------------------------------------
Object "steep slope"
with
  name 'steep' 'slope',
  description "The slope is very steep, making it difficult for you to walk.",
  found_in room11 room15 room16 room19,
has scenery;

!----------------------------------------
! Soil
!----------------------------------------
Object "soil" room16
with
  name 'soil',
  description "You've never seen such an arid place before.",
has scenery;

!========================================
! Room 17: Basin of Still Water South
!========================================
Object room17 "Basin of Still Water South"
with
  description 
  [;
    print"The southern part of the basin doesn't seem much different from the other. You can go north to where you came from or proceed towards the east. ";
    if (self hasnt visited)
      "^^A monster of enormous size raises its hideous head above you, spraying foam and water all around, producing a horrifying sound through its large mouth bristling with razor-sharp teeth. You barely manage in your attempt to prevent the pod from capsizing as the monster turns menacingly towards you.";
    "";
  ],
  e_to 
  [;
    if (monster notin limbo)
      "You need to deal with the monster, first. It wouldn't be wise to turn your back to it.";
    return room12;
  ],
  n_to 
  [;
    if (monster notin limbo)
      "You need to deal with the monster, first. It wouldn't be wise to turn your back to it.";
    return room18;
  ],
  before
  [;
    Swim:
      deadflag = 1;
      print"You enter the river and try to swim to the opposite bank, but the water in the basin is full of highly acidic substances. ";
      if (suit hasnt worn)
        "Their corrosive power is fatal. ";
      else 
        print"At first, your pressure suit seems to resist and, for a brief moment, you think you might escape this trap. Soon, though, it starts melting. ";
      "It's over for you.";
  ],
has passable light;

!----------------------------------------
! Hideous monster
!----------------------------------------
Object monster "monster" room17
with
  name 'hideous' 'monster',
  description "It's truly terrifying. It looks like a cross-breed between a dinosaur and a shark.",
  life
  [;
    Attack:
      "You have no chance of destroying that monstrosity. It's better to find a way to keep it at a distance.";
  ],
  before
  [;
    Shoot:
      if (second == nothing && rifle in player)
      {
        print "(with the rifle)^";
        second = rifle;
      }
      if (second == nothing)
        "At least tell with what you want me to shoot.";
      if (second ~= rifle)
        "You can't be serious!";
      print"You start shooting at the monster and you wound it without making it retreat. For a moment you feel a sense of despair and almost give up.^^Then, you fire again, and keep firing at it with your photon rifle until the monster is finally defeated. With one last jerk before dying, it tries to hit you with a fierce blow, and the resulting wave thrusts you into the air. When the pod hits the ground you are thrown out of it and onto the shore. You hit your head and lose consciousness.^^Time passes and, when you regain consciousness, you realise you are inside a house. You sense a presence near you.^^";
      StopDaemon(self);
      move monster to limbo;
      move pod1 to room12;
      PlayerTo(room23);
      rtrue;
  ],
  daemon
  [;
    self.time_left++;
    switch (self.time_left)
    {
      2: "^The monster swims around the pod, studying you as a shark would. It's considering its next move.";
      3: "^The monster gives a first bite to the pod, tearing a part away.";
      4: "^The monster starts moving toward you. You need to act now!";
      6: StopDaemon(self);
        deadflag = 1;
        "^The monster grabs your suit with its razor-sharp teeth. The rest is just a horrid scene of violent death.";
    }
  ],
  time_left 0,
has animate neuter scenery;

!========================================
! Room 18: Basin of Still Water North
!========================================
Object room18 "Basin of Still Water North"
with
  description
  [;
    print"Around you, the vast surface of a basin of still water, on which your pod floats, seems to have no end. To the east, is the expanse of sand you came from. ";
    if (monster notin limbo)
      "The basin expands towards the south, where you think you can see something moving. You should go there and check.";
    "The basin expands further towards the south.";
  ],
  e_to 
  [;
    if (monster notin limbo)
      "You think you can see something moving towards the south. You should go there and check.";
    return room13;
  ],
  s_to
  [;
    if (monster notin limbo)
      StartDaemon(monster);
    return room17;
  ],
  before
  [;
    Swim:
      deadflag = 1;
      print"You enter the river and try to swim to the opposite bank, but the water in the basin is full of highly acidic substances. ";
      if (suit hasnt worn)
        "Their corrosive power is fatal. ";
      else 
        print"At first, your pressure suit seems to resist and, for a brief moment, you think you might escape this trap. Soon, though, it starts melting. ";
      "It's over for you.";
  ],
has passable light;

!----------------------------------------
! Basin of water (floating object)
!----------------------------------------
Object basin "water basin"
with
  parse_name
  [ nw;
    nw = NextWord();
    if (nw == 'water')
    {
      if (NextWord() == 'basin')
        return 2;
      if (TestScope(water))
        return 0;
      return 1;
    }
    if (nw == 'basin')
      return 1;
    return 0;
  ],
  description
  [;
    if ((real_location == room12) || (real_location == room13))
      "The basin is quite wide, and extends north to south.";
    "Crossing the water basin seems the only way to go.";
  ],
  found_in room12 room13 room17 room18,
has scenery;

!========================================
! Room 19: Bottom of Crater
!========================================
Object room19 "Bottom of Crater"
with
  description "The bottom of the crater, at this point, is so uneven that it makes walking difficult and you risk your legs at every step you take. Towards the east the terrain becomes easier to walk, where a steep slope is the only way out from here. A large hole catches your attention.",
  e_to room15,
  in_to
  [;
    if (rifle notin player)
      "It could be dangerous down there, and you don't have any weapon with you.";
    if (rod hasnt general)
       "It could be dangerous down there, and it looks like your weapon is not ready to shoot.";
    if ((exoskeleton hasnt worn) && (aliens has general))
      "You've already been down there, and you know there's no way to come back up without the exoskeleton.";
    PlayerTo(room14);
    rtrue;
  ],
  d_to
  [;
    <<Enter hole>>;
  ],
has light;

!----------------------------------------
! Large hole (floating object)
!----------------------------------------
Object hole "large hole"
with
  name 'large' 'hole',
  description
  [;
    if (player in room19)
      "It's a large hole, big enough for you to enter, leading underground.";
    "It's a large hole above you, and apparently the only way out from here.";
  ],
  before
  [;
    Enter:
      if (self in room19)
      {
        if (rifle notin player)
          "It could be dangerous down there, and you don't have any weapon with you.";
        if (rod hasnt general)
          "It could be dangerous down there, and it looks like your weapon is not ready to shoot.";
        if ((exoskeleton hasnt worn) && (aliens has general))
          "You've already been down there, and you know there's no way to come back up without the exoskeleton.";
      }
      <<Go FAKE_IN_OBJ>>;
    Exit:
      if (self in room14)
      {
        if (exoskeleton has worn)
          <<Go FAKE_OUT_OBJ>>;
        else
          "The hole is out of your reach.";
      }    
  ],
  found_in room14 room19,
has scenery;

!========================================
! Room 20: Edge of Gravel-Strewn Surface
!========================================
Object room20 "Edge of Gravel-Strewn Surface"
with
  description "You've reached the edge of a large, arid, gravel-strewn surface. Except for the gravel, there's nothing else on this terrain. Your way back is towards the north while, towards the south, you think you can see a large metal object. You can also go east and west.",
  n_to room05,
  s_to room22,
  e_to room20,
  w_to room20,
has light;

!----------------------------------------
! Gravel-strewn surface (floating object)
!----------------------------------------
Object "gravel-strewn surface"
with
  name 'edge' 'expanse' 'of' 'large' 'arid' 'gravel-strewn' 'gravel' 'strewn' 'surface' 'terrain',
  description "Just gravel and more gravel. The heat is unbearable here.",
  found_in room06 room20 room21,
has scenery;

!----------------------------------------
! Large Metal Object
!----------------------------------------
Object "large metal object" room20
with
  name 'large' 'metal' 'object' 'remains',
  description
  [;
    if (room22 hasnt visited)
      "It could be part of your ship and, if it is, you hope to find something still usable inside. You need to get closer to be sure.";
    "It's the remains of the ship's security section.";
  ],
has scenery;

!========================================
! Room 21: Gravel-Strewn Surface
!========================================
Object room21 "Gravel-Strewn Surface"
with
  description "From here, a vast, arid, gravel-strewn surface extends northward, eastward and westward. You can go back to the edge of the channel by going south.",
  n_to room21,
  s_to room06,
  e_to room21,
  w_to room21,
has light;

!========================================
! Room 22: Near Remains of Security Section
!========================================
Object room22 "Near Remains of Security Section"
with
  description "You're standing near the remains of the sturdy airtight compartment that was part of the security section of the spaceship with which you crashed onto this planet. To the north, a vast desert stretches as far as the eye can see.",
  n_to room20,
has light;

!----------------------------------------
! Remains of security section
!----------------------------------------
Object "remains of security section" room22
with
  name 'remains' 'of' 'security' 'section' 'large' 'metal' 'object',
  description "The crash has torn the ship into pieces. This is one of them.",
has scenery;

!----------------------------------------
! Airtight compartment
!----------------------------------------
Object "airtight compartment" room22
with
  name 'airtight' 'compartment',
  description "This compartment used to hold the escape pod, together with your pressure suit and helmet. In the frantic moments before the crash, you only had time to enter the pod.",
has scenery;

!----------------------------------------
! Fireproof locker
!----------------------------------------
Object locker "fireproof locker" room22
with 
  name 'fireproof' 'locker',
  description
  [;
    print"This locker is used to store sensitive equipment. An alphanumeric keypad on the locker allows you to open it. ";
    <<Search self>>;
  ],
  before
  [;
    Shoot:
      if (second == nothing)
        "At least tell with what you want me to shoot.";
      if (second ~= rifle)
        print_ret (string)CANT_SHOOT_ANYTHING_WITH, (ThatOrThose)second, ".";
      if (second == rifle && rifle notin player)
        "You're not holding the rifle.";
      if ((rifle in player) && (rod hasnt general))
        "You try to shoot the locker but you realise the rifle isn't loaded.";
      "You take aim, ready to shoot the locker, but then you remember it holds something very important, so you desist.";        
  ],
  with_key dummy_key,
has container lockable locked openable static;

!----------------------------------------
! Pressure suit
!----------------------------------------
Object suit "pressure suit" locker
with
  name 'pressure' 'suit',
  description "This pressure suit is perfect for surviving in extreme conditions. It will protect you from the heat and the radiations, while providing breathable oxygen.",
  before
  [;
    Disrobe:
      if (self hasnt worn)
        "You are not wearing it.";
      print"You almost died while trying to retrieve your suit. You'd better keep it on. ";
      if (helmet has worn)
        "Besides, you should remove your helmet first.";
      "";
  ],
  daemon
  [;
    self.time_left++;
    switch (self.time_left)
    {
      9: "^You're starting to feel weak. The atmosphere of this planet is not suitable for your respiratory system.";
      15: "^It's getting more and more difficult to breathe. You need to retrieve your protective gear.";
      20: "^Your breathing has now become a rattle. A few more minutes and it will be over for you.";
      25: "^You need to do something now!";
      27: StopDaemon(self);
         deadflag = 1;
         "^You bend under the weight of your body, now heavy and cold as lead. With a last laboured breath, you give in to your fatal destiny and gradually lose consciousness, sliding towards the darkness.";
    }
  ],
  time_left 0,
has clothing;

!----------------------------------------
! Pressure helmet
!----------------------------------------
Object helmet "pressure helmet" locker
with
  name 'pressure' 'helmet',
  description
  [;
    print"The helmet completes the suit and provides full protection ";
    if (helmet has worn)
      "now that it's worn.";
    "once worn.";
  ],
  before
  [;
    Disrobe:
      if (helmet hasnt worn)
        "You are not wearing it";
      if ((location ~= room07) && (location ~= room12) && (location ~= room14) &&(location ~= room24) && (location ~= room23) && (location ~= room25))
        "If you take it off here, you'll start suffocating again. You'd better keep it on, until you find a safe place.";
    Wear:
      if (suit hasnt worn)
        "You try to put the helmet on, then realise it would be pretty silly since you are not wearing the suit yet, so you put it in your inventory again.";
      StopDaemon(suit);
      give helmet worn;
      "As you put the helmet on, the suit starts to pressurize. The flow of cool, breathable oxygen brings you back to your senses. As long as you're wearing your gear, you should be safe anywhere on the planet.";
  ],
has clothing;

!----------------------------------------
! RIM (Radiation Intensity Meter)
!----------------------------------------
Object meter "RIM (Radiation Intensity Meter)" locker
with
  name 'rim' 'radiation' 'intensity' 'meter',
  description 
  [;
    if ((crystals in player) && (player notin room14))
      "The RIM detects a source of radiation very close to you, possibly sensing the crystals you have in your inventory. However, the radiation level is not lethal to your body.";
    print "It's a small instrument that indicates the current level of radiation. According to it, the present location is ";
    switch (location)
    {
      room11, room16: " a source of faint radiation.";
      room14: "a highly-radioactive area. It's probably related to the massive presence of blue crystals.";
      room15, room19, room24: "a source of distinctive radiation.";
      default:
        "clear of any radiation.";
    }
  ],
has;

!----------------------------------------
! Keypad on the fireproof locker
!----------------------------------------
Object keypad "keypad" room22
with
  name 'alphanumeric' 'keypad' 'pad',
  description
  [;
		print "You can type an authentication code into it to open the locker. It looks like it can accept alphanumeric sequences. ";
		if (self hasnt general) 
      "What could that code be?";
		"The keypad is fried and doesn't work any more.";
	],
  before 
  [;
    Open, SwitchOn, Touch:
      "It's asking for a code.";
    SwitchOff:
      "Don't bother with this.";
  ],
has scenery;

!========================================
! Room 23: Inside Strange Construction
!========================================
Object room23 "Inside Strange Construction"
with
  description 
  [;
    print"You're inside a strange construction that resembles a typical terrestrial house, but it's very bare and lacks furniture. ";
    if (room23 hasnt general)
      "The only exit is out.";
    "You can go out the front of the construction or proceed south to reach Markus.";
  ],
  n_to room07,
  out_to room07,
  s_to "You cannot go south at this moment.",
  before
  [;
    Hint:
      if (room23 hasnt general)
        "Maybe you should ask Markus about his starship?";
  ],
has light;

!----------------------------------------
! Room
!----------------------------------------
Object "room" room23
with
  name 'furniture',
  description "There's almost nothing here, and the little you see doesn't seem important.",
has scenery;

!----------------------------------------
! Earthling
!----------------------------------------
Object markus "Markus" room23 
with
  name 'markus' 'earthling' 'old' 'man',
  initial 
  [; 
    if (self hasnt general)
      print"An old man ";
    else 
      print"Markus ";
    "stands in front of you.";
  ],
  description
  [;
    if (self hasnt general)
      "You're pretty sure he's your father's best friend, Markus, but you can't tell at first; you haven't seen him for 15 years and he now has a long straggly beard. He's not wearing a helmet, so either the air is cleaner in this part of the planet or, through the years, he got used to its atmosphere. You should try talking to him.";
    "He's Markus, the first man who managed to escape from Thalos. He's not wearing a helmet, so either the air is cleaner in this part of the planet or, through the years, he got used to its atmosphere.";  
  ],
  life
  [;
    Ask:
      if (self hasnt general)
        "You should talk to him first, before asking specific questions.";
      wn = consult_from;
      switch (NextWord())
      {
        'spaceship', 'starship', 'ship':
          print"~Unlike you, I was able to land on this planet with only minor maintenance problems. I didn't have enough fuel to resume my journey though, so I was only able to map part of the planet. When I finished the fuel, I hid the ship nearby and went out in search of some xelon, without finding it.~^";
          if (room23 hasnt general)
            print"^~Please follow me~ you hear him saying.^^Markus exits the house through a southern exit you hadn't noticed before.^";
          room23.s_to = room25;
          give room23 general;
          move markus to room25;
          rtrue;
        'alchemists':
          "~They are the original Thalos inhabitants. They are almost exactly like us, as you know. Which possibly means we have common ancestors. Unlike us, they developed psychic powers more than physical strength, and the possibility to understand the inner working of the universe much better than we do.~";
        'aliens':
          "~They come once a year, and stay a few weeks. Once I understood their pattern, I went out exploring to understand what they are doing. I suppose they are breeding a new kind of species, but I could never venture too far, since my equipment is very limited.~";
        'atmosphere':
          "~It's a little better here, while in the rocky terrains it gets so thin to be deadly if you stay out too long without proper equipment. However, through the years, I adapted to it a bit.";
        'stone', 'bridge':
          "~It used to connect the island with the mainland, but it collapsed a couple of years ago due to an earthquake. I had lost hope, but you are now here.~";
        'colony', 'settlers':
          "~We were the first, coming from Earth, to establish on Thalos. We thought it was a deserted planet, so the alchemists were actually a blessing for us. They helped us so much in the first years. Then, Fhenor become deranged.~";
        'eclipse', 'glitch':
          "~The eclipse disturbs Fhenor's sensors, and this is what allowed us to escape.~";
        'escape':
          "~I was able to leave Thalos thanks to the eclipse. Should I have some xelon crystals, I would be able to leave this planest as well.~";
        'experiments':
          "They are breeding a new kind of species, but I don't know anything else about it.";
        'father':
          "~Oh, he's passed away? I am so sad about that. He was my best friend, and I know he really cared about you. Actually, everything we did, including using the eclipse glitch to escape the planet, was in the attempt to secure a better future for you and all of Thalos' settlers.~";
        'fhenor', 'darkscepter':
          "~He was a good guy, or so we thought back then. He was the most clever and charismatic of all of us, the initial settlers sent from Earth to Thalos to start a colony. Then, he became greedy and obsessed with power, and a peaceful colony was turned into a land to tame.~";
        'earth':
          "~It's our home, the place from where we come from. If we don't find a way to stop Fhenor, it could fall as Thalos did.~";
        'fuel':
          "~The ship runs on xelon, a mineral that can be found also on this planet in the form of blue crystals.~";
        'him', 'himself', 'man', 'markus':
          "~Who? Me? I was a pilot, like you and your father before you. But, being one of the first settlers, I was also trained to be able to accomplish many different tasks. That's how I managed to escape, with the help of the alchemists.~";
        'island':
          "~It was actually a peninsula, that I chose since it was easy to defend from predators. Now we are stuck here, it seems.~";
        'machine', 'equipment','incubator', 'machinery':
          "~It is a kind of incubator. I don't know anything else.~";
        'me', 'myself', 'morgan':
          "~You are Morgan Tyler, the son of my best friend. You resemble your father, and seem to have the same kind heart.~";
        'monster':
          "~It was scary, wasn't it? How did you manage to survive, now that you make me think about it?~";
        'planet':
          "~It's not more than a piece of rock in the middle of an uncharted star system. Maybe that's why those aliens are using it as a test bed for their experiments.~";
        'predators':
          "Way too many and way too big. But it's quieter, on this side of the planet.";
        'solium', 'rod':
          "~The solium is a component we use to power our photon rifles, but you already know it. Don't you?~";
        'tasks':
          "~Besides piloting, I was also trained in basic life-support systems maintenance, resuscitation maneuvers, and engine repairing. You know, when you are light years away from home, help cannot come soon and you need to deal with that.~";
        'thalos':
          "~It's a wonderful place, in its own specific way, but it seems like we ruined it. Well, Fhenor did, but we are partly guilty because, at a certain point, we saw it coming, but we turned our heads away until it was too late.~";
        'blue', 'crystals', 'xelon':
          "~The xelon? It forms the basis of the warp engine's technology. Just a few crystals are enough to take off and leave this deadly place, but after the stone bridge collapsed I had no way to get them. Do you happen to have some?~";
        default:
          "~I don't know anything about that.~";
      }
    Give:
      if (noun == crystals)
      {
        if (room23 hasnt general)
          "~Don't you want to ask me about my spaceship first?~";
        deadflag = 2;
        "As you take the xelon and hand it to Markus, the old man's eyes fill up with tears. You managed to survive until you found your father's friend, the one who was able to flee from your planet fifteen years ago during the eclipse.^^Now that you have brought him the precious xelon crystals, the both of you will be able to leave this planet aboard the spaceship Markus repaired, finally reach Earth and, hopefully, come back to Thalos with the help that the planet desperately needs.^^Your story is just beginning, and further adventures await you in the future.";
      }
      else
        "~You keep it. I have no use for it.~";
    Show:
      if (noun == crystals)
        "The man's eyes widen in awe. Maybe you should give them to him.";
    Talk:
      if (markus hasnt general)
      {
        give markus general;
        "~Morgan? Is it really you? I haven't seen you in ages~ the old man says. ~How did you get here?~^^
        It looks like you finally found your father's best friend, the one who managed to escape Thalos by exploiting the eclipse glitch. In brief, he explains to you how he got here with the ship, and how he has survived through the years, rationing supplies and harvesting the meager fruits of this desolate planet.^^You could ask him a few questions, if you like.";
      }
      "~Do you have any more question you want to ask me?~"; 
  ],
  before
  [;
    Shoot:
      if (CantBeShot())
        rtrue;
      "Have you gone insane? This man has done you nothing. Besides, he's possibly your only way out from this forgotten piece of rock.";
  ],
has animate proper;

!========================================
! Room 24: Long Tunnel
!========================================
Object room24 "Long Tunnel"
with
  description "The long tunnel disappears to the west in the thickest darkness, and, to the east, it emerges into the cavity from which you came. The air seems breathable, here.",
  e_to
  [;
    if (aliens hasnt general)
      StopDaemon(aliens);
    return room14;
  ],
  w_to
  [;
    if (aliens hasnt general)
      "You cannot proceed westbound with the aliens in your way.";
    if (self hasnt general)
    {
      give self general;
      "It's dark, really dark, over there. I wouldn't suggest going.";
    }
    deadflag = 1;
    "You advance into the darkness without fear, but suddenly the ground gives way under your feet and you fall into a terrifying chasm. It's over for you.";
  ],
has light;

!----------------------------------------
! Group of aliens
!----------------------------------------
Object aliens "group of aliens" room24
with
  name 'group' 'of' 'aliens',
  initial 
  [;
    if (aliens hasnt general)
      "A group of aliens is inside the long tunnel.";
    "After you took them by surprise, the aliens are now harmless. Their weapons pose no danger to you any more.";
  ],
  description
  [;
    if (aliens hasnt general)
      "The aliens are working on some kind of machinery, and are not paying attention to you. They are cradling weapons in their arms, so they are likely to be very dangerous. ";
    else
      "They now lie dead on the ground, clutching their weapons with their claws.";
  ],
  life
  [;
    Ask, Talk:
      print "You have never seen this species before, so you do not know which kind of language they might speak. ";
      if (aliens has general)
        print"Besides, they now lie dead on the ground; I doubt they would be very responsive.";
      "";
    Attack:
      if (aliens hasnt general)
        "Indeed! But you need to be more specific.";
      "Since they are already dead, I suppose there's no need to.";
    Give, Show:
      if (aliens hasnt general)
        "This move would only get you killed.";
      "Since they are already dead, I suppose they are not very interested.";
  ],
  before
  [;
    Eat:
      "How do you want them cooked, sir?";
    Shoot:
      if (second == nothing && rifle in player)
      {
        print "(with the rifle)^";
        second = rifle;
      }
      if (second == nothing)
        "At least tell with what you want me to shoot.";
      if (second ~= rifle)
        print_ret (string)CANT_SHOOT_ANYTHING_WITH, (ThatOrThose)second, ".";
      if (self has general)
        "That's what we call 'overkill', and it's not needed.";
      if (second == rifle && rifle notin player)
        "You're not holding the rifle.";
      if (rifle in player)
      {
        if (rod hasnt general)
        {
         deadflag = 1;
         "As you take aim on the aliens, you realise that you never loaded the rifle, so they have all the time to take aim on you and blast you with their weapons. You fall to the ground, dead. What an ugly way to end your days!";
        }
        else
        {
          StopDaemon(self);
          give self general;
          "You open fire with your photon rifle. The energy beams pierce the aliens one by one, throwing them everywhere. As they are now lying dead on the ground, you can take a look around.";
        }
      }
    Take:
      "You'd better not.";
  ],
  daemon
  [;
    self.time_left++;
    print "^The aliens ";
    switch (self.time_left)
    {
      1: "are working on the strange machinery.";
      2: "suddenly stop, as if sensing your presence. You'd better think of something.";
      3: "stopped working again. One of them turns his gaze in your direction. Either do something or leave the place.";
      4: StopDaemon(self);
        deadflag = 1;
        "launch themselves at you and your efforts are useless. The aliens are incredibly strong and do not take long to kill you.";
    }
  ],
  time_left 0,
has animate neuter pluralname transparent;

!----------------------------------------
! Alien weapons
!----------------------------------------
Object weapons "weapons" aliens
with
  name 'weapons',
  description
  [;
    print"They look like powerful energy weapons";
    if (rifle in player)
      " like the one you are holding.";
    ". You wish you had one too.";
  ],
  before
  [;
    Take:
      if (aliens hasnt general)
        "Are you feeling suicidal?";
      "You already have your own weapon. You don't need any more.";
  ],
has scenery pluralname;

!----------------------------------------
! Strange equipment 
!----------------------------------------
Object alien_equipment "strange equipment" room24
with
  article "some",
  name 'strange' 'equipment' 'incubator' 'machine' 'machinery' 'pulsating',
  description
  [;
    if (aliens hasnt general)
      "With the aliens in the way you can't really see what it is.";
    "You have no idea what this equipment is for and, for the time being, you don't want to know. If you were to guess, it looks like an incubator. Inside it, something seems to be pulsating and moving slowly, but you can't make out what it is.";
  ],
  before 
  [;
    Attack, Shoot:
      if (aliens hasnt general)
        "How do you propose to do that? Those aliens are in the way.";
      "You'd better not. You don't know what it contains and how dangerous it could be.";
  ],
has static;

!----------------------------------------
! Strange mushrooms
!----------------------------------------
Object mushrooms "mushrooms" room24
with
  name 'alien' 'mushrooms',
  description "These mushrooms seem to prosper inside the underground tunnel and look enticing. Still, they are alien mushrooms on an alien planet.",
  before
  [;
    Eat:
      if (helmet has worn)
        "How do you think you can eat them while wearing your helmet?";
      if (self hasnt general)
      {
        give self general;
        "I don't think you should eat those mushrooms.";
      }
      deadflag = 1;
      "After swallowing the mushrooms, you feel that your body's metabolism is undergoing a biological alteration, but you cannot understand what has actually happened inside you. For a moment you feel a new strenght in your body, but a moment after your stomach starts to hurt. The pain is unbearable, and this is just the beginning... of your end.";
    Take:
      if (aliens hasnt general)
        "You can't take them while the aliens are in the way.";
  ],
has edible pluralname;

!----------------------------------------
! Exoskeleton
!----------------------------------------
Object exoskeleton "exoskeleton" room24
with
  article "an",
  name 'exoskeleton' 'exo' 'skeleton',
  description "It's a military-grade powered exoskeleton. It boosts your physical strength up by many times.",
  before
  [;
    Enter, Take:
      if (aliens hasnt general)
        "You can't take it while the aliens are in the way.";
      print"The exoskeleton is actually very heavy to carry along in your inventory, so you slip into it and secure it to your suit. Now you can lift up mountains.";
      move exoskeleton to player;
      give exoskeleton worn;
      "";
    Disrobe:
      if (crystals in player)
      {
        if (player in pod1)
          move crystals to pod1;
        else
          move crystals to location;
        print"Without the exoskeleton the crystals are too heavy to be carried, so you drop them.^";
      }
      if (pod1 in player)
      {
        move pod1 to location;
        print"Without the exoskeleton the pod is too heavy to be carried, so you drop it.^";
      }
      give exoskeleton ~worn;
      print"You slip out of the exoskeleton, which now lies ";
      if (player in pod1)
      {
        move exoskeleton to pod1;
        "inside the pod.";
      }
      else 
      {
        move exoskeleton to location;
        "on the ground.";
      }
  ],
has clothing;

!========================================
! Room 25: Clearing
!========================================
Object room25 "Clearing"
with
  description 
  [;
    "This clearing now accommodates Markus' ship. There's not much to be seen, as everything looks almost the same on this bare planet. From here you can go back north towards the house.";
  ],
  n_to room23,
has light;

!----------------------------------------
! Ship
!----------------------------------------
Object ship2 "ship" room25
with
  name 'ship',
  description "It's the ship Markus used to escape Thalos. It's still in good shape, but it seems to lack fuel.",
  before
  [;
    Enter:
      "The ship is not yet ready for take off. Should you have some fuel, you should give it to Markus, first.";
  ],
has static;

!========================================
! Limbo
!========================================
Object limbo;

!----------------------------------------
! Dummy key
!----------------------------------------
Object dummy_key;

!========================================
! Printing rules
!========================================
[ consultWord word i;
  for (i=0:i<WordLength(word):i++)
    print (char)LowerCase(WordAddress(word)->i);
];

[ DoesntOrDont obj;
  if (obj has pluralname)
    print "don't";
  else
    print "doesn't";
];

[ firstConsultWord word i;
  for (i=0:i<WordLength(word):i++)
    if (i == 0)
      print (char)UpperCase(WordAddress(word)->i);
    else
      print (char)LowerCase(WordAddress(word)->i);
];

!========================================
! Other routines
!========================================
[ _UpdateDarkness p_silent _ceil _old_darkness _darkness;
  if (location == thedark)
    _old_darkness = true;
  _ceil = ScopeCeiling(player);
  if (_LookForLightInObj(_ceil, _ceil) == false)
    _darkness = true;
  if (_darkness ~= _old_darkness)
    scope_modified = true;
  if (_darkness)
    location = thedark;
  else
    location = real_location;
  if (_darkness ~= _old_darkness && p_silent == false)
  {
    new_line;
    <Look>;
  }
];

[ CantBeShot;
  if (second == nothing && rifle in player)
  {
    print "(with the rifle)^";
    second = rifle;
  }
  if (second == nothing)
    "You have no weapon.";
  if (second ~= rifle)
    "You can't shoot anything with ", (ThatOrThose)second, ".";
  if (second == rifle && (rod hasnt general))
    "You pull the trigger, but nothing happens. The rifle charge must be down to zero.";
  rfalse;
];

[ LowerCase c; ! for ZSCII matching ISO 8859-1
  switch (c)
  {
    'A' to 'Z': c = c + 32;
    202, 204, 212, 214, 221: c--;
    217, 218: c = c - 2;
    158 to 160, 167, 168, 208 to 210: c = c - 3;
    186 to 190, 196 to 200: c = c - 5 ;
    175 to 180: c = c - 6;
  }
  return c;
];

[ PlayerDescription;
  print"You are Morgan Tyler, citizen number 7768 of class NDN. ";
  if (ship hasnt general)
    "You are about to board your ship and start your journey towards Earth. You need to seek help and try to save Thalos from its dictator.";
  print"After fleeing from Thalos, you are now stranded on an unknown planet. You need to find a way to escape this rock and reach Earth. ";
  if (suit hasnt worn)
    "You'd better find your gear before you suffocate.";
  "";
];

[ UpperCase c; ! for ZSCII matching ISO 8859-1
  switch (c)
  {
    'a' to 'z': c = c - 32;
    201, 203, 211, 213, 220: c++;
    215, 216: c = c + 2;
    155 to 157, 164, 165, 205 to 207: c = c + 3;
    181 to 185, 191 to 195: c = c + 5 ;
    169 to 174: c = c + 6;
  }
  return c;
];

!========================================
! Grammar
!========================================
Extend 'ask'
  * 'about' topic -> AskAbout;

Extend 'lock' first
  * noun -> Lock;

Extend 'look'
  * 'into' noun -> Search
  * 'behind'/'under' noun -> LookUnder;

Extend 'push' first
  * noun 'to'/'into' noun -> Push;

Extend 'read' first
  * noun -> Read;

Extend only 'say' first
  * topic -> Say;

Extend only 'speak' replace
  * -> Talk
  * creature -> Talk
  * noun -> Talk
  * 'to'/'with' creature -> Talk
  * 'to'/'with' noun -> Talk
  * 'to'/'with' creature 'about' topic -> Ask
  * 'to'/'with' noun 'about' topic -> Ask;

Extend 'unlock' first
  * noun -> Unlock;

Verb meta 'about' 'info'
  * -> About;

Verb meta 'credits'
  * -> Credits;

Verb meta 'help' 'instructions'
  * -> Help;

Verb 'hint' 'clue'
  * -> Hint;

Verb 'inspect' = 'examine';

Verb 'load'
  * noun -> Load
  * noun 'with' held -> Load;

Verb 'shoot'
  * -> Shoot
  * noun -> Shoot
  * noun 'with' held -> Shoot
  * 'at' noun -> Shoot
  * 'at' noun 'with' held -> Shoot
  * held 'at' noun -> Shoot reverse;

Verb 'talk' 'babble' 'chat' 'communicate' 'converse' 'gab' 'gossip'
  * -> Talk
  * creature -> Talk
  * noun -> Talk
  * 'to'/'with' creature -> Talk
  * 'to'/'with' noun -> Talk
  * 'to'/'with' creature 'about' topic -> Ask
  * 'to'/'with' noun 'about' topic -> Ask;

Verb 'type'  * -> TypeErr
             * special -> TypeErr
             * special 'on'/'into'/'in' -> TypeErr
             * special 'on'/'into'/'in' noun -> Type;

Verb 'use'
  * noun -> Use;

Verb 'xyzzy' 'plover' 'plugh' 'yoho'
  * -> MagicWord;

!========================================
! Actions
!========================================
[ AboutSub;
  print "This game is an adaptation of the Italian adventure 'Morgan Tyler: Eclypse' by Bonaventura Di Bello. It was originally written using The Quill and Illustrator and published by Edizioni Hobby S.r.l. on the cover tape of 'Epic 3000', no. 7, December 1986 for the ZX Spectrum. It was later published on the cover tape of 'Explorer', no. 7, May 1987 for the Commodore 64 and MSX.^^The data was extracted from the C64 version using UnQuill, translated to English and rewritten for a modern audience with the original author's permission. The new version includes many enhancements that weren't in the original. The coding was done using Inform 6 and the PunyInform library.^^";
  <<Credits>>;
];

[ AskAboutSub x count npc;
  objectloop (x in location && x has animate && x ~= player)
  {
    count++;
    npc = x;
  }
  if (count == 0)
    "There's no one here to answer your questions.";
  if (count == 1)
    <<Ask npc noun>>;
  "As there are multiple characters here, you'll have to specify who to ask, e.g. ASK MAN ABOUT DOG.";
];

[ CreditsSub;
  "Original concept, game design and coding by Bonaventura Di Bello.^Technical assistance by Max Di Bello.^English translation and game skeleton by Garry Francis.^Game redesign and coding by Gianluca Girelli.^Play testing by Andrew Schultz, Charles Moore, Garry Francis, Pablo Martinez and Robert Eggleston.";
];

!Delete GoSub if diagonal directions are used
[ GoSub _prop;
  if (selected_direction == ne_to or nw_to or se_to or sw_to)
    "There are no diagonal directions in this game.";
  _prop = selected_direction;
#Iftrue RUNTIME_ERRORS > RTE_MINIMUM;
  if (_prop == 0)
    return _RunTimeError(ERR_INVALID_DIR_PROP);
#Endif;
  return GoDir(_prop);
];

[ HelpSub;
  "Tell me what to do using simple commands starting with a verb.^^Use LOOK (or L) to refresh the location description. Identify all the objects in the description and EXAMINE (or X) each one. Read responses carefully for hints.^^Use compass directions (N, S, E, W, U and D) to move around. Draw a map as you go.^^Use GET or TAKE to take objects and DROP to drop them again. Use WEAR to wear things like clothing and REMOVE to remove anything that's currently worn. Use INVENTORY (or I) to see what you're carrying and wearing.^^Use AGAIN (or G) to repeat the last command.^^Use UNDO to undo the last command if you make a mistake.^^Use SAVE to save the game and RESTORE to restore it again.^^There are over 100 verbs that you can use, so if something doesn't work, try a different verb or a different way of doing things. Use HINT if you get stuck.^^For full instructions, see the game page at <https://bdb-project.itch.io/eclipse>.";
];

[ HintSub;
  if ((ship has general) && (keypad hasnt general))
    "You need to find a pressure suit before it's too late. It was somewhere inside the ship.";
  "Examine everything you find and draw a map.";
];

[ LoadSub;
  if (ObjectIsUntouchable(noun))
    return;
  "That would be a neat trick.";
];

[ LockSub k;
  if (ObjectIsUntouchable(noun))
    rtrue;
  if (noun hasnt lockable)
  {
    PrintMsg(MSG_LOCK_NOT_A_LOCK, 'lock');
    rtrue;
  }
  if (noun has locked)
  {
    PrintMsg(MSG_LOCK_ALREADY_LOCKED);
    rtrue;
  }
  if (noun has open)
  {
    PrintMsg(MSG_LOCK_CLOSE_FIRST);
    rtrue;
  }
  k = RunRoutines(noun, with_key);
  if (k == nothing)
    "You can't see how to lock ", (ItOrThem)noun, ".";
  if (second == nothing && k ~= nothing && k in player)
  {
    second = k;
    print "(with ", (the)second, ")^";
  }
  if (second == nothing)
    "You don't have the key.";
  if (second ~= k)
  {
    PrintMsg(MSG_LOCK_KEY_DOESNT_FIT);
    rtrue;
  }
  give noun locked;
  run_after_routines_msg = MSG_LOCK_DEFAULT;
  run_after_routines_arg_1 = 'lock';
];

[ LookUnderSub;
  if (location == thedark)
    "But it's dark.";
  "You find nothing of interest.";
];

[ MagicWordSub;
  "You say the magic word and the terrible Fhenor DarkScepter, dictator of Thalos and ruler of the Aldebaran II system, appears before your eyes. The sight scares you so much that you have to regain your senses, and Fhenor disappears.";
];

[ ReadSub;
  if (ObjectIsUntouchable(noun))
    rtrue;
  "There's nothing legible on ", (ThatOrThose)noun, ".";
];

[ SaySub i;
  if (consult_words == 0)
    "You have nothing to say.";
  print "~";
  i = consult_from;
  print (firstConsultWord)i++;
  while (i < consult_from + consult_words)
    print " ", (consultWord)i++;
  print ".~^^";
  wn = consult_from;
  if (consult_words == 1 && NextWord() == 'xyzzy' or 'plover' or 'plugh' or 'yoho')
    <<MagicWord>>;
  if (AfterRoutines())
    return;
  "Nothing happens.";
];

[ ShootSub;
  if (noun == nothing)
    "You aim with your finger on a distant point on the horizon and say, ~Bang!~. How silly.";
  if (ObjectIsUntouchable(noun))
    rtrue;
  if (CantBeShot())
    rtrue;
  if (noun == player)
    "Are you feeling suicidal?";
  "There's no need to shoot everything you see. You might destroy something important.";
];

[ TalkSub;
  if (noun == nothing)
    "You start talking to no one in particular.";
  if (noun == player)
    "You start talking to yourself, but it's a one-sided conversation.";
  if (RunLife(noun, ##Talk))
    rtrue;
  print_ret (The)noun, " ", (IsOrAre)noun, " not very talkative.";
];

[ TypeSub;
  if (second == keypad) 
  {
	  if (keypad hasnt general)
    {
      if (noun == 7768)
        "~This code has expired. Please insert the new code.~";
      if (~~(noun == 'ndn')) 
        "~Access denied.~";
      else
      {
        give keypad general;
        give locker ~locked;
        give locker open;
        "With a loud click the locker opens revealing its interior. Then, a vivid blue flash shoots from the keypad, destroying its mechanism. A short circuit, perhaps?";
      }  
    }
    "The locker is now unlocked and the keypad is fried. There's no need to type the code again.";
  }
  if (second == locker)
    "It doesn't work. Try typing on the keypad, instead.";
  "You cannot type anything on that.";
];

[ TypeErrSub;
  print "You'll need to be more specific. The type command wants you to provide a number or a string and an object to type it on, e.g. TYPE 1234 ON/INTO <object>.^";
  noun = false;
];

[ UnlockSub k;
  if (ObjectIsUntouchable(noun))
    rtrue;
  if (noun hasnt lockable)
  {
    PrintMsg(MSG_UNLOCK_NOT_A_LOCK, 'unlock');
    rtrue;
  }
  if (noun hasnt locked)
  {
    PrintMsg(MSG_UNLOCK_ALREADY_UNLOCKED, 'unlock');
    rtrue;
  }
  k = RunRoutines(noun, with_key);
  if (k == nothing)
    "You can't see how to unlock ", (ItOrThem)noun, ".";
  if (second == nothing && k ~= nothing && k in player)
  {
    second = k;
    print "(with ", (the)second, ")^";
  }
  if (second == nothing)
    "You don't have the key.";
  if (second ~= k)
  {
    PrintMsg(MSG_UNLOCK_KEY_DOESNT_FIT);
    rtrue;
  }
  give noun ~locked;
  run_after_routines_msg = MSG_UNLOCK_DEFAULT;
  run_after_routines_arg_1 = 'unlock';
];

[ UseSub;
  if (ObjectIsUntouchable(noun))
    rtrue;
  "You'll have to be more explicit than that.";
];

End;