am-python/justfile at master · bdelwood/am-python · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
set shell := ["bash", "-eu", "-o", "pipefail", "-c"]

default:
    @just --list

sync:
    uv sync --group dev

fmt:
    cargo fmt --all
    uvx ruff format .

fmt-check target="all":
    just fmt-check-{{target}}

fmt-check-rs:
    cargo fmt --all -- --check

fmt-check-py:
    uvx ruff format --check .

fmt-check-all:
    just fmt-check-rs
    just fmt-check-py

lint target="all":
    just lint-{{target}}

lint-rs:
    cargo clippy --release

lint-py:
    uvx ruff check .

lint-all:
    just lint-rs
    just lint-py

typecheck:
    uv run --group dev pyrefly check

test target="all":
    just test-{{target}}

test-py:
    uv run --group dev pytest

test-rs:
    cargo test --release

test-all:
    just test-py
    just test-rs

precommit:
    uv run --group dev pre-commit run --all-files --show-diff-on-failure

prepush:
    uv run --group dev pre-commit run --all-files --hook-stage pre-push --show-diff-on-failure

docs target="all":
    just docs-{{target}}

docs-py:
    mkdir -p docs/_build/python
    uv run --group dev sphinx-build -W --keep-going -b html docs docs/_build/python

docs-rs:
    cargo doc --no-deps --document-private-items

docs-all:
    just docs-py
    just docs-rs
    rm -rf public
    mkdir -p public/rust
    cp -R docs/_build/python/. public/
    cp -R target/doc/. public/rust/