git-mob/flake.nix at main · code-supply/git-mob · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
{
  description = "A git-mob implementation in bash and jq";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
  };

  outputs = { self, nixpkgs }:
    let
      forAllSystems = generate: nixpkgs.lib.genAttrs [
        "aarch64-darwin"
        "x86_64-darwin"
        "aarch64-linux"
        "x86_64-linux"
      ]
        (system: generate (
          let
            pkgs = nixpkgs.legacyPackages.${system};
            callPackage = pkgs.lib.callPackageWith
              (pkgs // {
                version =
                  if self ? rev
                  then self.rev
                  else "dirty";
              });
          in
          {
            inherit pkgs;
            gitMob = callPackage ./default.nix { };
          }
        ));
    in
    {
      formatter = forAllSystems ({ pkgs, ... }: pkgs.nixpkgs-fmt);
      apps = forAllSystems
        ({ gitMob }: {
          default = {
            type = "app";
            program = gitMob;
          };
        });
      packages = forAllSystems ({ gitMob, ... }: {
        default = gitMob;
      });
      devShells = forAllSystems ({ pkgs, gitMob, ... }: {
        default = pkgs.mkShell {
          packages = [
            gitMob
            pkgs.dialog
            pkgs.nixpkgs-fmt
          ];
        };
      });
    };
}