dev-cli/flake.nix at main · csvenke/dev-cli · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-parts.url = "github:hercules-ci/flake-parts";
  };

  outputs =
    inputs@{
      self,
      flake-parts,
      nixpkgs,
      ...
    }:
    flake-parts.lib.mkFlake { inherit inputs; } {
      systems = nixpkgs.lib.systems.flakeExposed;
      perSystem =
        { system, ... }:
        let
          pkgs = import nixpkgs {
            inherit system;
            overlays = [
              (final: prev: {
                go = prev.go_1_26;
                buildGoModule = prev.buildGoModule.override { go = prev.go_1_26; };
              })
            ];
          };
          inherit (pkgs) lib callPackage;
          version = self.shortRev or self.dirtyShortRev or "snapshot";
          scripts = lib.packagesFromDirectoryRecursive {
            inherit callPackage;
            directory = ./nix/scripts;
          };
          dev-cli = callPackage ./nix/package.nix {
            inherit version;
          };
          shell = callPackage ./nix/shell.nix { };
        in
        {
          packages = scripts // {
            default = dev-cli;
          };
          devShells = {
            default = shell;
          };
        };
    };
}