mod.dang

"""
A Dagger module that uses the TypeScript SDK.
"""
type Mod {
  """
  Workspace-relative path of this module root.
  """
  pub path: String!

  """
  Workspace containing this module.
  """
  let ws: Workspace!

  """
  Marker filename that skips generate when found at or above this module root.
  """
  let skipGenerateFilename: String!

  """
  Whether this module or an ancestor contains the configured generate skip marker.
  """
  pub skipGenerate(ws: Workspace!): Boolean! {
    hasMarker(ws, skipGenerateFilename)
  }

  """
  Manage this module's Dagger dependencies.
  """
  pub deps: ModDeps! {
    ModDeps(
      path: path,
      ws: ws,
    )
  }

  """
  Manage the Dagger engine version required by this module.
  """
  pub engine: ModEngine! {
    ModEngine(
      path: path,
      ws: ws,
    )
  }

  """
  Whether this module root or an ancestor contains a marker filename.
  """
  let hasMarker(ws: Workspace!, filename: String!): Boolean! {
    let markerPath = ws.findUp(name: filename, from: path)
    markerPath != null
  }

  """
  Generate this module.
  If the generate skip marker is present, the changeset is empty.
  """
  pub generate(ws: Workspace!): Changeset! {
    if (skipGenerate(ws)) {
      polyfill.workspace(ws).fork.changes
    } else {
      polyfill.workspace(ws).moduleSource(path).generate.changes
    }
  }
}