Only depend on the runtime libraries from the Swift toolchain

Author: jketema

unified/swift-syntax-rs/BUILD.bazel

@@ -1,8 +1,14 @@
 load("@rules_rust//rust:defs.bzl", "rust_binary", "rust_library", "rust_test")
+load(":swift_runtime.bzl", "swift_runtime_libs")
 load(":xcode_transition.bzl", "xcode_transition_swift_library")
 
 package(default_visibility = ["//visibility:public"])
 
+swift_runtime_libs(
+    name = "swift_runtime_libs",
+    toolchain = "@swift_toolchain_ubuntu24.04//:files",
+)
+
 # Targets in this package require a Swift toolchain (Linux or macOS).
 # `select()` gives us OR-of-OSes; other platforms get marked incompatible
 # so `bazel build/test //...` skips them cleanly.
@@ -50,7 +56,7 @@ rust_binary(
     # `xcode_swift_toolchain`).
     data = select({
         "@platforms//os:macos": [],
-        "@platforms//os:linux": ["@swift_toolchain_ubuntu24.04//:files"],
+        "@platforms//os:linux": [":swift_runtime_libs"],
     }),
     edition = "2024",
     target_compatible_with = _SWIFT_SUPPORTED_PLATFORMS,
@@ -63,7 +69,7 @@ rust_test(
     crate = ":swift_syntax_rs",
     data = select({
         "@platforms//os:macos": [],
-        "@platforms//os:linux": ["@swift_toolchain_ubuntu24.04//:files"],
+        "@platforms//os:linux": [":swift_runtime_libs"],
     }),
     edition = "2024",
     target_compatible_with = _SWIFT_SUPPORTED_PLATFORMS,

unified/swift-syntax-rs/swift_runtime.bzl

@@ -0,0 +1,19 @@
+"""Filter the Swift toolchain down to just its Linux runtime shared objects.
+
+The standalone toolchain's `:files` bundles the compiler, host libraries, clang
+runtime, plugins, etc. For running a Swift-linked binary we only need the
+runtime shared objects in `usr/lib/swift/linux/`.
+"""
+
+def _swift_runtime_libs_impl(ctx):
+    libs = [
+        f
+        for f in ctx.files.toolchain
+        if "/usr/lib/swift/linux/" in f.path and f.path.endswith(".so")
+    ]
+    return [DefaultInfo(files = depset(libs))]
+
+swift_runtime_libs = rule(
+    implementation = _swift_runtime_libs_impl,
+    attrs = {"toolchain": attr.label(allow_files = True)},
+)