hack for separate note piles

[hermanhel]

Here is a hack to have separate note piles. I use this to make org-node-find wrapper commands that have different org-node-filter-fn, such as with a certain tag, under a directory, etc.

(defvar custom-org-node--candidate<>entry (make-hash-table :test 'equal)
  "1:1 table mapping minibuffer completion candidates to ID-nodes.
These candidates may or may not be pre-affixated, depending on
user option `org-node-alter-candidates'.")

(defvar custom-org-node--title<>affixations (make-hash-table :test 'equal)
  "1:1 table mapping titles or aliases to affixation triplets.
Even when the triplets are not used, this table serves double-duty such
that its keys constitute the subset of `org-mem--title<>id' that
passed `org-node-filter-fn'.")

(defmacro custom-with-tables (&rest form)
  `(let ((org-node--candidate<>entry custom-org-node--candidate<>entry)
         (org-node--title<>affixations custom-org-node--title<>affixations))
     ,@form))

(custom-with-tables
 (let ((org-node-filter-fn #'my-org-node-filter-fn))
   (org-node-find)))

These tables are not cached with org-node-cache-mode. I added prefix to the wrapper that does org-node-reset with the tables and do it manually. Works for me.

(defun custom-visit (arg)
  (interactive "P")
  (custom-with-tables
   (let ((org-node-filter-fn #'custom-org-node-filter))
     (when (= (car arg) 4)
       (org-node-reset))
       (org-mem-await "caching for custom candidates..." 60)
     (org-node-find))))

replace custom with something else for other candidate set.

It is reasonable that a more multiplexing version could be derived where one can select candidate sets, such as with (org-node-find-with-candidates CANDIDATES-SET-NAME), having an alist of CANDIDATES-SET-NAME and its associated 2 hashtables and possibly org-node-filter-fn and org-node-affixation-fn.

[hermanhel]

This is the multiple version.

(defun org-mem-have-tags-p-2nd-order (test-tags)
  "note: used eval here, so test-tags can execute arbitrary code.
Better keep it to string only."
  (eval `(lambda (entry)
           (let ((tags (org-mem-tags entry)))
             (-all? (lambda (tag) (-contains? tags tag))
                    (list ,@test-tags))))))

(defvar org-node-candidates-set-config
  `((tag1
     ,(make-hash-table :test 'equal)
     ,(make-hash-table :test 'equal)
     ,(org-mem-have-tags-p-2nd-order (list "tag1"))
     org-node-prepend-olp-append-tags-use-frame-width)))
(defun org-node-find-with-candidates-set-2nd-order (candidates-set-name)
  "return an interactive lambda that visits a candidates-set, with
C-u prefix set to reset the cache"
  (eval `(lambda (arg)
           (interactive "P")
           (-let (((org-node--candidate<>entry
                    org-node--title<>affixations
                    org-node-filter-fn
                    org-node-affixation-fn)
                   (cdr (assoc ',candidates-set-name org-node-candidates-set-config))))
             (when (and arg (= (car arg) 4))
               (org-node-reset)
               (org-mem-await "caching..." 60))
             (org-node-find)))))

(defun org-node-insert-with-candidates-set-2nd-order (candidates-set-name)
  "return an interactive lambda that visits a candidates-set, with
C-u prefix set to reset the cache"
  (eval `(lambda (arg)
           (interactive "P")
           (-let (((org-node--candidate<>entry
                    org-node--title<>affixations
                    org-node-filter-fn
                    org-node-affixation-fn)
                   (cdr (assoc ',candidates-set-name org-node-candidates-set-config))))
             (when (and arg (= (car arg) 4))
               (org-node-reset)
               (org-mem-await "caching for ahharocks-eval..." 60))
             (org-node-insert-link)))))
;; with doomemacs's map!
(map! :leader
      "e v v" (org-node-find-with-candidates-set-2nd-order 'tag1))

[meedstrom]

Interesting! Thanks for posting.

Do you get any delay when you switch back and forth between the commands custom-visit and org-node-find?

EDIT: Ah, I see, it only resets with C-u anyway. Not bad.

[meedstrom]

If you don't mind my hijacking the thread a bit:

I have been thinking that maybe org-node should have a way to rebuild its two cache tables (those you override here, org-node--candidate<>entry and org-node--title<>affixations) much more often, since it's usually cheap.

It'd solve the minor problem that when the option org-node-filter-fn is set to org-node-append-tags-use-frame-width and the user then resizes the frame, the user has to manually reset to get it to look right again.

But also: the topic of this thread. A good design could make it easier to implement new features like separate note piles. Not sure what that design would be, feel free to chime in if you have an opinion! Or like, what you expected about how hard it was gonna be?

Maybe the tables can rebuild every single time that org-node-read-candidate is invoked! That would effectively disable the cache behavior (mod a couple of functions like org-node-all-filtered-nodes needing a rewrite if the programmer is to be free to assume that there is no caching going on, i.e. no reuse of old results anywhere, but let's set that aside for now).

Many other Emacs commands build their completion candidates in real-time and it's fine. (It'll of course be nice to keep the option to use cache, in case of an expensive custom lambda for org-node-filter-fn or some truly slow hardware.)

If I remember my dev decisions, the main reason that org-node only rebuilds when org-mem does is because org-mem used to be part of org-node. The two mentioned tables are simply those that remained with us after that separation of concerns. They don't actually need to stay in lockstep with org-mem, which is nice, as you've found.

I guess the first step to make it easier can be an alternative to org-node--record-completion-candidates-all that can be called with no argument at any time, i.e. does not need to be passed the input argument from the hook it's on currently. Something like

(defun org-node-rebuild-completions ()
  (org-node--wipe-completions nil)
  (dolist (entry (org-mem-all-entries))
    (org-node--record-completion-candidates entry)
    (org-node--let-refs-be-aliases entry)))

Theoretically, that could replace both org-node-reset and org-mem-await in your custom-visit command. If it performs well it could even be done every call and not only when C-u.

Not at a computer currently so can't test that.