publish snapshots

Author: hauner

build.gradle

@@ -3,11 +3,12 @@ plugins {
     id 'java-library'
     id 'maven-publish'
     id 'com.jfrog.bintray' version '1.8.5'
+    id 'com.jfrog.artifactory' version '4.15.2'
     id "com.github.ben-manes.versions" version "0.28.0"
 }
 
-group 'io.openapiprocessor'
-version '1.1.0.M1-SNAPSHOT'
+group projectGroupId
+version projectVersion
 
 java {
     sourceCompatibility = JavaVersion.VERSION_1_8
@@ -41,34 +42,4 @@ artifacts {
     archives javadocJar
 }
 
-bintray {
-    user = bintrayUser
-    key = bintrayKey
-    publications = ['api']
-
-    pkg {
-        repo = 'primary'
-        userOrg = 'openapi-processor'
-        name = 'openapi-processor-api'
-        licenses = ['Apache-2.0']
-        vcsUrl = 'https://github.com/openapi-processor/openapi-processor-api'
-
-        version {
-            name = project.version
-        }
-    }
-}
-
-publishing {
-    publications {
-        api (MavenPublication) {
-            from components.java
-            artifact sourcesJar
-            artifact javadocJar
-
-            groupId project.group
-            artifactId project.name
-            version project.version
-        }
-    }
-}
+apply from: "${rootProject.rootDir}/gradle/publishing.gradle"

gradle.properties

@@ -0,0 +1,8 @@
+projectVersion=1.1.0.M1-SNAPSHOT
+projectGroupId=io.openapiprocessor
+
+projectUrl=http://openapiprocessor.io
+projectTitle=openapi-processor
+projectDesc=converts OpenAPI yaml descriptions to a target format, e.g. Java code (Spring) or json
+
+projectGithubRepo=openapi-processor/openapi-processor-api

gradle/publishing.gradle

@@ -0,0 +1,81 @@
+def pomConfig = {
+    licenses {
+        license {
+            name 'The Apache Software License, Version 2.0'
+            url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
+            distribution "repo"
+        }
+    }
+    developers {
+        developer {
+            id 'hauner'
+            name 'Martin Hauner'
+        }
+    }
+
+    scm {
+       url "https://github.com/${project.projectGithubRepo}".toString ()
+    }
+}
+
+publishing {
+    publications {
+        projectArtifacts (MavenPublication) {
+            from components.java
+            artifact sourcesJar
+            artifact javadocJar
+
+            groupId project.group
+            artifactId project.name
+            version project.version
+
+            pom.withXml {
+                def root = asNode()
+                root.appendNode('name', project.projectTitle)
+                root.appendNode('description', project.projectDesc)
+                root.appendNode('url', project.projectUrl)
+                root.children().last() + pomConfig
+            }
+        }
+    }
+}
+
+
+artifactory {
+    contextUrl = 'https://oss.jfrog.org'
+    publish {
+        repository {
+            repoKey = 'oss-snapshot-local'
+            username = bintrayUser
+            password = bintrayKey
+        }
+        defaults {
+            publications('projectArtifacts')
+            publishArtifacts = true
+            publishPom = true
+        }
+    }
+    resolve {
+        repoKey = 'jcenter'
+    }
+}
+
+
+bintray {
+    user = bintrayUser
+    key = bintrayKey
+    publications = ['projectArtifacts']
+
+    pkg {
+        repo = 'primary'
+        name = project.name
+        userOrg = 'openapi-processor'
+        licenses = ['Apache-2.0']
+        vcsUrl = "https://github.com/${project.projectGithubRepo}".toString ()
+        websiteUrl = projectUrl
+        desc = "${project.projectTitle} - ${project.projectDesc} - ${project.name} module".toString()
+        version {
+            name = project.version
+        }
+    }
+}