VolumeEngine/meson.build at master · tas0dev/VolumeEngine · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
project(
        'VolumeEngine',
        'c',
        version : '0.1.0',
        meson_version : '>=1.3.0',
        default_options : [
                'c_std=c99',
                'warning_level=3',
                'werror=true',
        ],
)

cc = meson.get_compiler('c')

sdl3 = dependency('sdl3')
opengl = dependency('gl')
epoxy = dependency('epoxy')
assimp = dependency('assimp')
math = cc.find_library('m', required : true)

volume_dependencies = [
        sdl3,
        opengl,
        epoxy,
        assimp,
        math,
]

volume_sources = files(
        'src/volume.c',
        'src/platform/platform.c',
        'src/core/log.c',
        'src/core/path.c',
        'src/entity/entity.c',
        'src/entity/builtin.c',
        'src/entity/prop_static.c',
        'src/entity/light_environment.c',
        'src/entity/world.c',
        'src/entity/properties.c',
        'src/renderer/renderer.c',
        'src/renderer/mesh.c',
        'src/renderer/shader.c',
        'src/renderer/material.c',
        'src/renderer/shadow_map.c',
        'src/renderer/hdr_buffer.c',
        'src/renderer/bloom_buffer.c',
        'src/renderer/texture.c',
        'src/math/mat4.c',
        'src/math/vec3.c',
        'src/scene/camera.c',
        'src/scene/transform.c',
        'src/input/input.c',
        'src/map/keyvalues.c',
        'src/map/map.c',
        'src/map/spawn.c',
        'src/asset/manager.c',
        'src/asset/mesh_loader.c',
        'src/asset/material_loader.c',
        'src/collision/aabb.c',
        'src/collision/triangle.c',
        'src/collision/box_collider.c',
        'src/collision/triangle_mesh_collider.c',
        'src/collision/collision_world.c',
        'src/collision/collider.c',
        'src/physics/character_controller.c',
)

volume_include = include_directories(
        'src',
        'libs',
)

volume_library = static_library(
        'volumeengine',
        volume_sources,
        dependencies : volume_dependencies,
        include_directories : volume_include,
        install : false,
)

volume_dependency = declare_dependency(
        link_with : volume_library,
        dependencies : volume_dependencies,
        include_directories : volume_include,
)

subdir('examples')
subdir('tests')