agent-shell/agent-shell-github.el at main · xenodium/agent-shell · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
;;; agent-shell-github.el --- GitHub Copilot agent configurations -*- lexical-binding: t; -*-

;; Copyright (C) 2024 Alvaro Ramirez

;; Author: Alvaro Ramirez https://xenodium.com
;; URL: https://github.com/xenodium/agent-shell

;; This package is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 3, or (at your option)
;; any later version.

;; This package is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.

;;; Commentary:
;;
;; This file includes GitHub Copilot-specific configurations.
;;

;;; Code:

(eval-when-compile
  (require 'cl-lib))
(require 'shell-maker)
(require 'acp)

(declare-function agent-shell--indent-string "agent-shell")
(declare-function agent-shell-make-agent-config "agent-shell")
(autoload 'agent-shell-make-agent-config "agent-shell")
(declare-function agent-shell--make-acp-client "agent-shell")
(declare-function agent-shell--dwim "agent-shell")

(defcustom agent-shell-github-acp-command
  '("copilot" "--acp")
  "Command and parameters for the GitHub Copilot agent client.

The first element is the command name, and the rest are command parameters."
  :type '(repeat string)
  :group 'agent-shell)

(defcustom agent-shell-github-default-model-id
  nil
  "Default GitHub Copilot model ID.

Must be one of the model ID's displayed under \"Available models\"
when starting a new shell."
  :type '(choice (const nil) string)
  :group 'agent-shell)

(defcustom agent-shell-github-default-session-mode-id
  nil
  "Default GitHub Copilot session mode ID.

Must be one of the mode ID's displayed under \"Available modes\"
when starting a new shell."
  :type '(choice (const nil) string)
  :group 'agent-shell)

(defcustom agent-shell-github-environment
  nil
  "Environment variables for the GitHub Copilot agent client.

This should be a list of environment variables to be used when
starting the GitHub Copilot agent process."
  :type '(repeat string)
  :group 'agent-shell)

(defun agent-shell-github-make-copilot-config ()
  "Create a GitHub Copilot agent configuration.

Returns an agent configuration alist using `agent-shell-make-agent-config'."
  (agent-shell-make-agent-config
   :identifier 'copilot
   :mode-line-name "Copilot"
   :buffer-name "Copilot"
   :shell-prompt "Copilot> "
   :shell-prompt-regexp "Copilot> "
   :icon-name "githubcopilot.png"
   :welcome-function #'agent-shell-github--welcome-message
   :client-maker (lambda (buffer)
                   (agent-shell-github-make-client :buffer buffer))
   :default-model-id (lambda () agent-shell-github-default-model-id)
   :default-session-mode-id (lambda () agent-shell-github-default-session-mode-id)
   :install-instructions "See https://github.com/github/copilot-cli for installation."))

(defun agent-shell-github-start-copilot ()
  "Start an interactive GitHub Copilot agent shell."
  (interactive)
  (agent-shell--dwim :config (agent-shell-github-make-copilot-config)
                     :new-shell t))

(cl-defun agent-shell-github-make-client (&key buffer)
  "Create a GitHub Copilot agent ACP client with BUFFER as context."
  (unless buffer
    (error "Missing required argument: :buffer"))
  (when (and (boundp 'agent-shell-github-command) agent-shell-github-command)
    (user-error "Please migrate to use agent-shell-github-acp-command and eval (setq agent-shell-github-command nil)"))
  (agent-shell--make-acp-client :command (car agent-shell-github-acp-command)
                                :command-params (cdr agent-shell-github-acp-command)
                                :environment-variables agent-shell-github-environment
                                :context-buffer buffer))

(defun agent-shell-github--welcome-message (config)
  "Return GitHub Copilot welcome message using `shell-maker' CONFIG."
  (let ((art (agent-shell--indent-string 4 (agent-shell-github--ascii-art)))
        (message (string-trim-left (shell-maker-welcome-message config) "\n")))
    (concat "\n\n"
            art
            "\n\n"
            message)))

(defun agent-shell-github--ascii-art ()
  "GitHub Copilot ASCII art matching the official CLI banner."
  (let* ((is-dark (eq (frame-parameter nil 'background-mode) 'dark))
         (text (string-trim "
  █████┐ █████┐ █████┐ ██┐██┐     █████┐ ██████┐
 ██┌───┘██┌──██┐██┌─██┐██│██│    ██┌──██┐└─██┌─┘
 ██│    ██│  ██│█████┌┘██│██│    ██│  ██│  ██│
 ██│    ██│  ██│██┌──┘ ██│██│    ██│  ██│  ██│
 └█████┐└█████┌┘██│    ██│██████┐└█████┌┘  ██│
  └────┘ └────┘ └─┘    └─┘└─────┘ └────┘   └─┘
" "\n")))
    (propertize text 'font-lock-face (if is-dark
                                         '(:foreground "#6e40c9" :inherit fixed-pitch)
                                       '(:foreground "#8250df" :inherit fixed-pitch)))))

(provide 'agent-shell-github)

;;; agent-shell-github.el ends here