struct-patch/flake.nix at main · yanganto/struct-patch · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
{

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-25.11-small";
    rust-overlay.url = "github:oxalica/rust-overlay";
    flake-utils.url = "github:numtide/flake-utils";
    dependency-refresh.url = "github:yanganto/dependency-refresh";
  };

  outputs = { self, rust-overlay, nixpkgs, flake-utils, dependency-refresh }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        overlays = [ (import rust-overlay) ];
        pkgs = import nixpkgs {
          inherit system overlays;
        };
        dr = dependency-refresh.defaultPackage.${system};

        publishScript = pkgs.writeShellScriptBin "crate-publish" ''
          cargo login $1
          cargo publish -p struct-patch-derive || echo "publish struct-patch-derive fail"
          sleep 10
          cargo publish -p struct-patch
        '';
        checkCatalystScript = pkgs.writeShellScriptBin "check-catalyst" ''
          cd $(git rev-parse --show-toplevel 2>/dev/null)
          cd complex-example
          cargo test -p substrate
          cargo test -p catalyst
        '';
        updateDependencyScript = pkgs.writeShellScriptBin "update-dependency" ''
          dr ./Cargo.toml

          cd no-std-examples
          dr ./Cargo.toml

          cd ../complex-example
          dr ./Cargo.toml

          if [[ -f "Cargo.toml.old" || -f "no-std-examples/Cargo.toml.old" || -f "complex-example/Cargo.toml.old" ]]; then
            rm -f Cargo.toml.old
            rm -f no-std-examples/Cargo.toml.old
            rm -f complex-example/Cargo.toml.old
            exit 1
          fi
        '';
      in
      with pkgs;
      {
        devShells = let
          noStdRust = rust-bin.stable.latest.default.override {
            targets = [
              "thumbv7m-none-eabi"
            ];
            extensions = [ "rust-src" "llvm-tools-preview" ];
          };
        in
        {
          default = mkShell {
            buildInputs = [
              rust-bin.stable.latest.minimal
              openssl
              pkg-config

              checkCatalystScript
            ];
          };

          ci = mkShell {
            buildInputs = [
              rust-bin.stable.latest.default
              openssl
              pkg-config

              dr
              publishScript
              updateDependencyScript

              checkCatalystScript
            ];
          };

          no-std = mkShell {
            buildInputs = [
              noStdRust
              qemu
            ];
          };
        };
      }
    );
}